Technik Wiki
Registrieren
Advertisement
Gruppe: Grid Kolben
Vorrichtungen

Grid Roter Sand blass mit Mechaniken

Grid Redstone blass mit Redstone
                Hier:
Grid Befehlsblock mit Befehlen
Verfügbar in:
Wiki Redstone-Welt Redstone-Welt

Ein Drop-Sensor kann das Droppen und Aufsammeln aus dem Inventar erfassen. Hierbei kann das Droppen von beliebigen oder ganz bestimmten Gegenständen erfasst werden. Auch Drops die sich bereits außerhalb des Inventars befinden können erkannt werden. Ebenfalls lassen sich die Stapel-Anzahl damit auslesen. Gegenstände kann man mit Q droppen, wodurch dieser Sensor auch als Q-Tasten-Sensor benutzt werden kann, je nach Tastatur-Einstellung.

Variante 1[]

Drop-Sensor (Befehle) Bild 1.1 Drop-Sensor (Befehle) Bild 1.2

Mit dem Drop-Sensor kann man erfassen ob man irgendeinen Gegenstand gedroppt hat und ob ein oder mehrere Drops sich in der Nähe des Spielers befinden.

Einschalten
  • Befehl 1.1 Es wird ein Punkte-Ziel erstellt, dass das allgemeine Droppen von Gegenständen erfasen kann.
  • Befehl 1.2 Dem Spieler werden 64 Redstone, 64 Kolben[B1.3] und 64 Diamanten[B1.4] gegeben, die er droppen kann um sie vom Sensor erfassen zu lassen.
Wiederholen
  • Befehl 1.5 Spieler im Umkreis von 50 Blöcken, die Gegenstände gedroppt haben, erhalten eine Text-Nachricht, in der angezeigt wird, dass der Spieler gerade etwas gedroppt hat.
  • Befehl 1.6 Spieler die etwas gedroppt haben, bekommen den Wert auf null zurückgesetzt, damit sie die Nachricht nicht ein zweites mal erhalten.
  • Befehl 1.7 In einem Umkreis von 50 Blöcken, wird an der Position von Drops eine Schnellleisten-Nachricht an Spielern ausgesendet, die maximal fünf Meter vom Drop entfernt sind. Die Nachricht zeigt dem Spieler an, dass sich in der Nähe ein Drop befindet.
  • Befehl 1.8 Von Spielern im Umkreis von 50 Blöcken, wird getestet ob sich keine Drops in der Nähe befinden. Nur dann wenn das zutrifft erhalten sie eine Schnellleisten-Nachricht in der das angegeben wird, dass kein Drop in der Nähe sich befindet.
Ausschalten
  • Befehl 1.9 Das Punkte-Ziel wird entfernt und somit auch alle Werte die Spieler besaßen.
  • Befehl 1.10 Redstone, Kolben[B1.11] und Diamanten[B1.12] mit einer bestimmten Eigenschaft werden aus allen Spieler-Inventaren entfernt.
  • Befehl 1.13 Falls noch Drops auf dem Boden liegen, werden diese ebenfalls entfernt.

Befehlsblöcke mit Befehlen:
scoreboard objectives add PZDrSen.1Drop minecraft.custom:minecraft.drop ["Drop-Sensor.1: ",{"text":"Drops","bold":true}]
give @a[distance=..25] minecraft:redstone{EigDrSen.1Alle:true,display:{Lore:['"Wirf den Gegenstand mit Q"'] } } 64
give @a[distance=..25] minecraft:piston{EigDrSen.1Alle:true,display:{Lore:['"Wirf den Gegenstand mit Q"'] } } 64
give @a[distance=..25] minecraft:diamond{EigDrSen.1Alle:true,display:{Lore:['"Wirf den Gegenstand mit Q"'] } } 64


tellraw @a[distance=..50,scores={PZDrSen.1Drop=1..}] ["Drop-Sensor.1:\n",{"text":"gedroppt == ","bold":true},{"text":"wahr","color":"green","bold":true}]
scoreboard players set @a[distance=..50,scores={PZDrSen.1Drop=1..}] PZDrSen.1Drop 0
execute at @e[distance=..50,type=minecraft:item] run title @a[distance=..5] actionbar ["",{"text":"Drop in Nähe == ","bold":true},{"text":"wahr","color":"green","bold":true}]
execute as @a[distance=..50] at @s unless entity @e[distance=..5,type=minecraft:item,sort=nearest,limit=1] run title @s actionbar ["",{"text":"Drop in Nähe == ","bold":true},{"text":"falsch","color":"red","bold":true}]


scoreboard objectives remove PZDrSen.1Drop
clear @a minecraft:redstone{EigDrSen.1Alle:true}
clear @a minecraft:piston{EigDrSen.1Alle:true}
clear @a minecraft:diamond{EigDrSen.1Alle:true}
kill @e[type=minecraft:item,nbt={Item:{tag:{EigDrSen.1Alle:true} } }]

Variante 2[]

Drop-Sensor (Befehle) Bild 2.1 Drop-Sensor (Befehle) Bild 2.2

Mit diesem Drop-Sensor kann man nach bestimmten Gegenstände die gedroppt wurden abfragen. Ebenfalls kann mit diesem Sensor das Aufheben von bestimmten Gegenständen geprüft werden.

Einschalten
  • Befehl 2.1 Es werden fünf Punkte-Ziele erstellt. Eines für das Droppen an sich, zwei für das Droppen von Gold-[B2.2] und Eisenbarren[B2.3], zwei weitere für das Aufheben von Gold-[B2.4] und Eisenbarren[B2.5].
  • Befehl 2.6 Vor Spielern im Umkreis von 25 Blöcken wird Gold- und Eisenbarren gedroppt, welches aufeinander gestapelt sind.
Wiederholen
  • Befehl 2.7 Spieler die in einem Umkreis von 50 Blöcken etwas gedroppt haben und in deren Nähe innerhalb von fünf Blöcken sich der gedroppte und noch nicht etikettierte Goldbarren aufhält, erhalten eine Text-Nachricht, in der die genaue Anzahl, der bereits bis zu dem jetzigen Zeitpunkt gedroppten Goldbarren, angegeben wird.
  • Befehl 2.8 Wie beim Goldbarren wird auch beim Droppen des Eisenbarrens eine Text-Nachricht angezeigt in der die Anzahl der gedroppten Eisenbarren angegeben wird.
  • Befehl 2.9 Der gedroppte Gegenstand in der Nähe des Spielers erhält anschließend ein Etikett, damit er nicht erneut erfasst wird.
  • Befehl 2.10 Von der Position der Spieler, wird die jeweils genaue Anzahl von Drops in einem Umkreis von fünf Blöcken um den Spieler herum erfasst und in das Punkte-Ziel für das allgemeine Droppen gespeichert (Das Punkte-Ziel kann hier wieder verwendet werden, da das Droppen an sich bereits erfasst und ausgegeben wurde).
  • Befehl 2.11 Spieler im Umkreis von 50 Blöcken in deren Nähe sich mindestens ein Drop befindet, erhalten eine Schnellleisten-Nachricht, in der die genaue Anzahl von Dropps angegeben wird.
  • Befehl 2.12 Anschließend wird das Punkte-Ziel fürs Droppen bei allen Spielern die was gedroppt haben oder in deren Nähe sich Drops aufhalten, wieder auf null zurückgesetzt.
Ausschalten
  • Befehl 2.13 Die Punkte-Ziele für das allgemeine Droppen, für das Droppen von Gold-[B2.14] und Eisenbarren[B2.15] und für das Aufheben von Gold-[B2.16] und Eisenbarren[B2.17] werden entfernt.
  • Befehl 2.18 Gold- und Eisenbarren[B2.19] werden aus den Inventaren aller Spieler entfernt, sofern sie die spezielle Eigenschaft besitzen.
  • Befehl 2.20 Falls noch Drops auf dem Boden herum liegen werden sie ebenfalls entfernt.

Befehlsblöcke mit Befehlen:
scoreboard objectives add PZDrSen.2Drop minecraft.custom:minecraft.drop ["Drop-Sensor.2: ",{"text":"Droppen der Drops","bold":true}]
scoreboard objectives add PZDrSen.2AuDrop minecraft.dropped:minecraft.gold_ingot ["Drop-Sensor.2: ",{"text":"Gedroppe Goldbarren","bold":true}]
scoreboard objectives add PZDrSen.2FeDrop minecraft.dropped:minecraft.iron_ingot ["Drop-Sensor.2: ",{"text":"Gedroppe Eisenbarren","bold":true}]
scoreboard objectives add PZDrSen.2AuAuf minecraft.picked_up:minecraft.gold_ingot ["Drop-Sensor.2: ",{"text":"Aufgehobene Goldbarren","bold":true}]
scoreboard objectives add PZDrSen.2FeAuf minecraft.picked_up:minecraft.iron_ingot ["Drop-Sensor.2: ",{"text":"Aufgehobene Eisenbarren","bold":true}]
execute at @a[distance=..25] run summon minecraft:item ~ ~ ~ {Item:{id:"minecraft:gold_ingot",Count:64b,tag:{EigDrSen.2Alle:true,display:{Lore:['"Wirf den Gegenstand mit Q"'] } } },Passengers:[{id:"minecraft:item",Item:{id:"minecraft:iron_ingot",Count:64b,tag:{EigDrSen.2Alle:true,display:{Lore:['"Wirf den Gegenstand mit Q"'] } } } } ] }


execute as @a[distance=..50,scores={PZDrSen.2Drop=1..}] at @s if entity @e[distance=..5,type=minecraft:item,tag=!EtiDrSen.2Drop,nbt={Item:{id:"minecraft:gold_ingot",tag:{EigDrSen.2Alle:true} } }] run tellraw @s ["Drop-Sensor.2:",{"text":"\nGoldbarren gedroppt == ","color":"gold","bold":true},{"score":{"name":"@s","objective":"PZDrSen.2AuDrop"},"color":"dark_purple","bold":true},{"text":"\nGoldbarren aufgehoben == ","color":"gold","bold":true},{"score":{"name":"@s","objective":"PZDrSen.2AuAuf"},"color":"dark_purple","bold":true}]
execute as @a[distance=..50,scores={PZDrSen.2Drop=1..}] at @s if entity @e[distance=..5,type=minecraft:item,tag=!EtiDrSen.2Drop,nbt={Item:{id:"minecraft:iron_ingot",tag:{EigDrSen.2Alle:true} } }] run tellraw @s ["Drop-Sensor.2:",{"text":"\nEisenbarren gedroppt == ","color":"gray","bold":true},{"score":{"name":"@s","objective":"PZDrSen.2FeDrop"},"color":"dark_purple","bold":true},{"text":"\nEisenbarren aufgehoben == ","color":"gray","bold":true},{"score":{"name":"@s","objective":"PZDrSen.2FeAuf"},"color":"dark_purple","bold":true}]
execute at @a[distance=..50,scores={PZDrSen.2Drop=1..}] run tag @e[distance=..5,type=minecraft:item,tag=!EtiDrSen.2Drop,nbt={Item:{tag:{EigDrSen.2Alle:true} } }] add EtiDrSen.2Drop
execute as @a[distance=..50] at @s store result score @s PZDrSen.2Drop if entity @e[distance=..5,type=minecraft:item]
execute as @a[distance=..50,scores={PZDrSen.2Drop=1..}] run title @s actionbar ["",{"text":"Drops in Nähe == ","bold":true},{"score":{"name":"@s","objective":"PZDrSen.2Drop"},"color":"dark_purple","bold":true}]
scoreboard players set @a[scores={PZDrSen.2Drop=1..}] PZDrSen.2Drop 0


scoreboard objectives remove PZDrSen.2Drop
scoreboard objectives remove PZDrSen.2AuDrop
scoreboard objectives remove PZDrSen.2FeDrop
scoreboard objectives remove PZDrSen.2AuAuf
scoreboard objectives remove PZDrSen.2FeAuf
clear @a minecraft:gold_ingot{EigDrSen.2Alle:true}
clear @a minecraft:iron_ingot{EigDrSen.2Alle:true}
kill @e[type=minecraft:item,nbt={Item:{tag:{EigDrSen.2Alle:true} } }]

Variante 3[]

Drop-Sensor (Befehle) Bild 3.1 Drop-Sensor (Befehle) Bild 3.2

Dieser Drop-Sensor kann die Stapelgröße, den Gegenstand und die Verfallszeit des Drops erfassen und anzeigen. Droppt man etwas, so wird im Chat angezeigt wie groß der Stapel war, den man herausgeworfen hat. In der nähe liegende Drops zeige ihre Information über der Schnellleiste an.

Einschalten
  • Befehl 3.1 Ein Punkte-Ziel für das Droppen von Gegenständen wird erstellt.
  • Befehl 3.2 Spielern im Umkreis von 25 Blöcken werden Redstone-Fackeln, Eier[B3.3] und Boote[B3.4] gegeben.
Wiederholen
  • Befehl 3.5 Spieler die in einem Umkreis von 50 Blöcken sind und etwas gedroppt haben, lassen von ihrer Position aus die Stapelgröße des Drops auslesen und der Wert wird in ein Punkte-Ziel gespeichert.
  • Befehl 3.6 Von der Position des droppenden Spielers wird der erste Drop erfasst, der in einem Radius von fünf Blöcken um den Spieler herum liegt und noch nicht das Etikett besitzt und mindestens den Wert eins besitzt. Dann erhält der Spieler eine Text-Nachricht in der steht, dass er gedroppt hat und wie hoch die Stapel-Anzahl ist.
  • Befehl 3.7 Der soeben geworfene Drop erhält ein Etikett, damit er nicht erneut erfasst wird.
  • Befehl 3.8 Befindet sich in einem Radius von fünf Blöcken um den Spieler ein Drop, so wird dem Spieler über der Schnellleiste die ID, die Stapel-Anzahl und die Verfallszeit des Drops angezeigt.
Ausschalten
  • Befehl 3.9 Das Punkte-Ziel wird wieder entfernt.
  • Befehl 3.10 Redstone-Fackeln, Eier[B3.11] und Boote[B3.12] mit einer bestimmten Eigenschaft werden aus den Inventaren der Spieler entfernt.
  • Befehl 3.13 Drops die ein bestimmtes Etikett besitzen bekommen dieses entfernt.
  • Befehl 3.14 Alle Drops mit einem bestimmten Etikett werden gelöscht.

Befehlsblöcke mit Befehlen:
scoreboard objectives add PZDrSen.3Drop minecraft.custom:minecraft.drop ["Drop-Sensor.3: ",{"text":"Droppen der Drops","bold":true}]
give @a[distance=..25] minecraft:redstone_torch{EigDrSen.3Alle:true,display:{Lore:['"Wirf den Gegenstand mit Q"'] } } 64
give @a[distance=..25] minecraft:egg{EigDrSen.3Alle:true,display:{Lore:['"Wirf den Gegenstand mit Q"'] } } 32
give @a[distance=..25] minecraft:oak_boat{EigDrSen.3Alle:true,display:{Lore:['"Wirf den Gegenstand mit Q"'] } } 4


execute at @a[distance=..50,scores={PZDrSen.3Drop=1..}] as @e[distance=..5,type=minecraft:item,tag=!EtiDrSen.3Drop,sort=nearest,limit=1] store result score @s PZDrSen.3Drop run data get entity @s Item.Count
execute at @a[distance=..50,scores={PZDrSen.3Drop=1..}] as @e[distance=..5,type=minecraft:item,tag=!EtiDrSen.3Drop,scores={PZDrSen.3Drop=1..},sort=nearest,limit=1] run tellraw @p ["Drop-Sensor.3:",{"text":"\nStapel gedroppt == ","color":"gold","bold":true},{"score":{"name":"@s","objective":"PZDrSen.3Drop"},"color":"dark_purple","bold":true}]
execute at @a[distance=..50,scores={PZDrSen.3Drop=1..}] run tag @e[distance=..5,type=minecraft:item,tag=!EtiDrSen.3Drop,scores={PZDrSen.3Drop=1..},sort=nearest,limit=1] add EtiDrSen.3Drop
execute at @a[distance=..50] as @e[distance=..5,type=minecraft:item,sort=nearest,limit=1] run title @p actionbar ["",{"text":"ID == ","color":"gray","bold":true},{"entity":"@s","nbt":"Item.id","color":"dark_purple","bold":true},{"text":" Stapel == ","color":"gray","bold":true},{"entity":"@s","nbt":"Item.Count","color":"dark_purple","bold":true},{"text":" Zeit == ","color":"gray","bold":true},{"entity":"@s","nbt":"Age","color":"dark_purple","bold":true}]


scoreboard objectives remove PZDrSen.3Drop
clear @a minecraft:redstone_torch{EigDrSen.3Alle:true}
clear @a minecraft:egg{EigDrSen.3Alle:true}
clear @a minecraft:oak_boat{EigDrSen.3Alle:true}
tag @e[type=minecraft:item,tag=EtiDrSen.3Drop] remove EtiDrSen.3Drop
kill @e[type=minecraft:item,nbt={Item:{tag:{EigDrSen.3Alle:true} } }]

Variante 4[]

Drop-Sensor (Befehle) Bild 4.1 Drop-Sensor (Befehle) Bild 4.2

Mit diesem Drop-Sensor lässt sich erfassen, ob ein Block oder eine Kreatur (bzw. Objekt) Gegenstände nach dem Abbau oder Tod etwas droppen lässt. Dazu bekommt man zwei Stöcke mit einem Verzauberungsschimmer. Wählt man einen der Stöcke aus, so erhält man über der Schnellzugriffsleiste eine Nachricht in der steht, ob der Block oder die Kreatur droppen kann. Dies funktioniert so, dass man die Beute in eine stationäre Güterlore überträgt und ausließt ob diese befüllt wurde. In manchen Fällen kann die Nachricht ständig wechseln, dass liegt daran, dass eine Kreatur nicht immer etwas droppen muss, sondern nur mit einer bestimmten Wahrscheinlichkeit.

Einschalten
  • Befehl 4.1 Auf dem Wiederhol-Befehlsblock befindet sich ein Hebel. Legt man ihn um, wird zuerst der Befehlsblock mit der Start-Funktion drop-sensor:v4start aktiviert.
Wiederholen
Ausschalten

Befehlsblöcke mit Befehlen:



Variante 4: Start-Funktion
Die Start-Funktion erstellt die Güterlore die mit allen Spielern geteilt wird um das Droppen zu erfassen. Ebenfalls werden die Stöcke verteilt.

Editor Icon drop-sensor:v4start.mcfunction
# Ein Rüstungsständer wird erstellt, auf dem eine Güterlore platz findet.
summon minecraft:armor_stand ~ ~1 ~ {Small:true,Invisible:true,NoGravity:true,Tags:["EtiDrSen.4Alle"],Passengers:[{id:"minecraft:chest_minecart",NoGravity:true,Tags:["EtiDrSen.4Alle","EtiDrSen.4Sensor"]}]}

# Spieler im Umkreis von 25 Blöcken bekommen zwei Stöcke, welche für das Erfassen der droppenden Blöcke und Objekte benutzt werden können.
give @a[distance=..25] minecraft:stick{EigDrSen.4Alle:true,EigDrSen.4Block:true,Enchantments:[{id:-1}],display:{Name:'{"text":"Droppt Block?","color":"dark_purple","bold":true}',Lore:['"Wähle den Stock aus"','"um anzuzeigen zu lassen ob der"','"Block Drops hinterlassen kann"'] } }
give @a[distance=..25] minecraft:stick{EigDrSen.4Alle:true,EigDrSen.4Kreatur:true,Enchantments:[{id:-1}],display:{Name:'{"text":"Droppt Kreatur?","color":"dark_purple","bold":true}',Lore:['"Wähle den Stock aus"','"um anzuzeigen zu lassen ob die"','"Kreatur Drops hinterlassen kann"'] } }

Variante 4: Zyklus-Funktion
Die Zyklus-Funktion prüft ob die Spieler die Stöcke in der Schnellleiste ausgewählt haben und ruft nur dann die entsprechenden Funktionen auf.

Editor Icon drop-sensor:v4zyklus.mcfunction
# Wenn der Spieler auf dem Boden steht und den Stock ausgewählt hat, erhaält er ein Etikett.
tag @a[nbt={OnGround:true,SelectedItem:{id:"minecraft:stick",tag:{EigDrSen.4Alle:true} } }] add EtiDrSen.4Erfassen

# Nur wenn der Spieler einen der beiden Stöcke ausgewählt hat, wird die entsprechende Funktion durch ihn geladen.
execute as @a[tag=EtiDrSen.4Erfassen,nbt={SelectedItem:{tag:{EigDrSen.4Block:true} } }] run function drop-sensor:v4block
execute as @a[tag=EtiDrSen.4Erfassen,nbt={SelectedItem:{tag:{EigDrSen.4Kreatur:true} } }] run function drop-sensor:v4objekt

# Das Etikett wird bei allen Spielern die es besitzen wieder entfernt.
tag @a[tag=EtiDrSen.4Erfassen] remove EtiDrSen.4Erfassen

Variante 4: Block-Funktion
Die Block-Funktion lässt von einem Block direkt unterm Spieler die Beute in die Güterlore droppen um das Droppen dessen zu erfassen.

Editor Icon drop-sensor:v4block.mcfunction
# Zuerst wird die Güterlore geleert, bevor sie die Ausbeute des Blockes unterm Spieler erhält.
data remove entity @e[type=minecraft:chest_minecart,tag=EtiDrSen.4Sensor,sort=nearest,limit=1] Items
execute at @s run loot replace entity @e[type=minecraft:chest_minecart,tag=EtiDrSen.4Sensor] container.0 mine ~ ~-0.5 ~

# Falls die Güterlore Gegenstände beinhaltet, so kann der Block grundsätzlich droppen und dann erhält die Güterlore dafür ein Etikett.
tag @e[type=minecraft:chest_minecart,tag=EtiDrSen.4Sensor,nbt={Items:[{}]}] add EtiDrSen.4Droppt

# Wenn die Güterlore das Etikett besitzt erhält der Spieler eine positive Titel-Nachricht, ansonsten eine negative.
execute if entity @e[type=minecraft:chest_minecart,tag=EtiDrSen.4Sensor,tag=EtiDrSen.4Droppt] run title @s actionbar ["",{"text":"Block kann droppen == ","color":"gray","bold":true},{"text":"wahr","color":"green","bold":true}]
execute if entity @e[type=minecraft:chest_minecart,tag=EtiDrSen.4Sensor,tag=!EtiDrSen.4Droppt] run title @s actionbar ["",{"text":"Block kann droppen == ","color":"gray","bold":true},{"text":"falsch","color":"red","bold":true}]

# Das Etikett wird danach wieder entfernt.
tag @e[type=minecraft:chest_minecart,tag=EtiDrSen.4Sensor,tag=EtiDrSen.4Droppt] remove EtiDrSen.4Droppt

Variante 4: Objekt-Funktion
Die Objekt-Funktion lässt von einer Kreatur einweit vom Spieler die Beute in die Güterlore droppen und prüft darauf ob die Güterlore befüllt wurde.

Editor Icon drop-sensor:v4objekt.mcfunction
# Zuerst wird die Güterlore geleert, bevor sie die Ausbeute der nächstgelegenen Kreatur vom Spieler aus erhält.
data remove entity @e[type=minecraft:chest_minecart,tag=EtiDrSen.4Sensor,sort=nearest,limit=1] Items
execute at @s run loot replace entity @e[type=minecraft:chest_minecart,tag=EtiDrSen.4Sensor] container.0 kill @e[distance=..5,type=!minecraft:player,sort=nearest,limit=1]

# Falls die Güterlore Gegenstände beinhaltet, so kann der Block grundsätzlich droppen und dann erhält die Güterlore dafür ein Etikett.
tag @e[type=minecraft:chest_minecart,tag=EtiDrSen.4Sensor,nbt={Items:[{}]}] add EtiDrSen.4Droppt

# Wenn die Güterlore das Etikett besitzt erhält der Spieler eine positive Titel-Nachricht, ansonsten eine negative.
execute if entity @e[type=minecraft:chest_minecart,tag=EtiDrSen.4Sensor,tag=EtiDrSen.4Droppt] run title @s actionbar ["",{"text":"Objekt kann droppen == ","color":"gray","bold":true},{"text":"wahr","color":"green","bold":true}]
execute if entity @e[type=minecraft:chest_minecart,tag=EtiDrSen.4Sensor,tag=!EtiDrSen.4Droppt] run title @s actionbar ["",{"text":"Objekt kann droppen == ","color":"gray","bold":true},{"text":"falsch","color":"red","bold":true}]

# Das Etikett wird danach wieder entfernt.
tag @e[type=minecraft:chest_minecart,tag=EtiDrSen.4Sensor,tag=EtiDrSen.4Droppt] remove EtiDrSen.4Droppt

Variante 4: Stopp-Funktion
Die Stopp-Funktion löscht die Stöcke wieder samt Etiketten, Güterlore und Drops.

Editor Icon drop-sensor:v4stopp.mcfunction
# Die Stöcke werden wieder entfernt.
clear @a minecraft:stick{EigDrSen.4Alle:true}

# Das Etikett wird entfernt.
tag @a[tag=EtiDrSen.4Erfassen] remove EtiDrSen.4Erfassen

# Damit die Güterlore nichts droppt, wird ihr Inhalt gelöscht.
data remove entity @e[type=minecraft:chest_minecart,tag=EtiDrSen.4Sensor,sort=nearest,limit=1] Items

# Alle Objekte mit dem Etikett werden gelöscht.
tag @e[type=minecraft:item,nbt={Item:{tag:{EigDrSen.4Alle:true} } }] add EtiDrSen.4Alle
kill @e[tag=EtiDrSen.4Alle]


Disambig color
Grid Grasblock
Auch im Minecraft Wiki wird das Thema dieser Technik behandelt:
Drop
Advertisement