Technik Wiki
Registrieren
Advertisement
Gruppe: Grid Kolben
Vorrichtungen

Grid Roter Sand mit Mechaniken

Grid Redstone blass mit Redstone
                Hier:
Grid Befehlsblock mit Befehlen
Verfügbar in:
Wiki Redstone-Welt Redstone-Welt

Ein Dropgenerator kann Gegenstände zu einer festgelegten Zeit immer wieder erzeugen. Diese hier sind besonders bei Minispiele sehr nützlich, da sie den Spielern einen Vorrat an bestimmten Barren liefern. Man kann auch den Dropgenerator in Kombination einer Tauschmaschine nutzen, sodass man die hier erhaltenen Drops gegen andere Blöcke oder Gegenstände tauschen kann, um beispielsweise Waffen oder Werkzeuge zu bekommen.

Die unten gezeigten Dropgeneratoren werden vor allem im sehr bekannten Minispiel Bedwars verwendet.

Variante 1

Dropgenerator (Befehle) Bild 1.1

Mit dieser Variante lassen sich Bronzegeneratoren durch das Platzieren von Rüstungsständern erzeugen. an der platzierten Stelle wird ein Ziegelstein gesetzt der nach einer bestimmten Zeit einen Bronzebarren erzeugt.

Einschalten

Beim Einschalten wird ein Punktestand-Ziel erstellt und die Spieler erhalten Bronzebarrengeratoren in die Hand.

  • Befehl 1.1 Das Punktestand-Ziel für die Zeit wird erstellt. Welches genutzt wird um den Zeitpunkt zu ermitteln, wann ein neuer Bronzebarren erzeugt werden soll.
  • Befehl 1.2 Der Bronzegenerator in Form von Rüstungsständern wird allen Spielern in einem Umkreis von 15 Metern mitgegeben.
Wiederholen

Alle 200 Ticks wird ein Bronzebarren an der Stelle des Generators erzeugt und beim Platzieren von diesem wird Ziegelstein platziert.

  • Befehl 1.3 Wenn sich an der Position des Rüstungsständers noch kein Block befindet, wird ein Ziegelstein dort platziert.
  • Befehl 1.4 Jeden Tick wird der Wert, aller Rüstungsständer die in der Welt platziert wurden, um eins erhöht.
  • Befehl 1.5 Sobald der die Bronzegenerator-Rüstungsständer den Wert 20 erreichen wird an deren Position einen Meter höher ein Bronzebarren erzeugt, der noch ein wenig in die Lüfte springt.
  • Befehl 1.6 Wenn der Bronzegenerator-Rüstungsständer den Wert 200 oder höher besitzt, wird der Wert wieder auf null zurückgesetzt.
Ausschalten

Das Punktestand-Ziel, sowie alle Bronzegeneratoren, alle Bronzebarren und Gegenstände im Inventar werden gelöscht.

  • Befehl 1.7 Das Punktestand-Ziel für die Zeitfeststellung wird gelöscht
  • Befehl 1.8 An der Position der Bronzebarrengeneratoren wird zuerst geprüft ob dort Ziegelsteine sich befinden und erst dann wird dieser entfernt.
  • Befehl 1.9 Falls noch Drops auf dem Boden liegen, erhalten sie ein Etikett um erkannt zu werden.
  • Befehl 1.10 Alle Bronzegeneratoren und eventuell herumliegende Drops werden gelöscht.
  • Befehl 1.11 Rüstungsständer die als Bronzegenerator arbeiten, werden aus dem Inventar entfernt.
  • Befehl 1.12 Bronzebarren die aufgesammelt wurden, werden aus dem Inventar entfernt.

Befehlsblöcke mit Befehlen:
scoreboard objectives add PZDropG.1Zeit dummy ["Dropgenerator.1: ",{"text":"Zeit bis ein Bronzebarren erscheint","bold":true}]
give @a[distance=..15] minecraft:armor_stand{dropgenerator:"v1gegenstand",display:{Name:'{"text":"Bronzegenerator","bold":true}',Lore:['"Platziere den Rüstungsständer"','"auf dem Boden"','"um einen Bronzegenerator"','"zu kreieren"']},EntityTag:{Small:true,NoGravity:true,Invisible:true,Tags:["EtiDropG.1Alle"]} } 16


execute at @e[type=minecraft:armor_stand,tag=EtiDropG.1Alle] run setblock ~ ~ ~ minecraft:bricks keep
scoreboard players add @e[type=minecraft:armor_stand,tag=EtiDropG.1Alle] PZDropG.1Zeit 1
execute at @e[type=minecraft:armor_stand,tag=EtiDropG.1Alle,scores={PZDropG.1Zeit=20}] run summon minecraft:item ~ ~1 ~ {Item:{id:"minecraft:brick",Count:1b,tag:{dropgenerator:"v1gegenstand",display:{Name:'{"text":"Bronzebarren"}'} } },Motion:[0.0d,0.3d,0.0d],Tags:["EtiDropG.1Alle"] }
scoreboard players reset @e[type=minecraft:armor_stand,tag=EtiDropG.1Alle,scores={PZDropG.1Zeit=200..}] PZDropG.1Zeit


scoreboard objectives remove PZDropG.1Zeit
execute at @e[type=minecraft:armor_stand,tag=EtiDropG.1Alle] if block ~ ~ ~ minecraft:bricks run setblock ~ ~ ~ minecraft:air replace
tag @e[type=minecraft:item,nbt={Item:{tag:{dropgenerator:"v1gegenstand"} } }] add EtiDropG.1Alle
kill @e[tag=EtiDropG.1Alle]
clear @a minecraft:armor_stand{dropgenerator:"v1gegenstand"}
clear @a minecraft:brick{dropgenerator:"v1gegenstand"}

Variante 2

Dropgenerator (Befehle) Bild 2.1

Wie bereits bei der ersten Variante können auch hier durch Rüstungsständer Generatoren platziert werden. Hierbei erhält man die Möglichkeit Generatoren für Bronze-, Eisen- und Goldbarren zu platzieren. Sie erzeugen nach einer gewissen Zeit entsprechende Barren, die man aufsammeln kann.

Einschalten
  • Befehl 2.1 Auf dem Wiederhol-Befehlsblock befindet sich ein Hebel. Legt man ihn um, wird zuerst der Befehlsblock mit der Startfunktion dropgenerator:v2start aktiviert.
Wiederholen
Ausschalten

Befehlsblöcke mit Befehlen:



Variante 1: Start-Funktion
Es wird das Punktestand-Ziel für das Hochzählen der Zeit erstellt, sowie die Rüstungsständer in die Hand der Spieler gegeben, die man als Generatoren auf den Boden platzieren kann.

Editor Icon dropgenerator:v2start.mcfunction
# Das Punktestand-Ziel für die Zeitmessung wird erstellt
scoreboard objectives add PZDropG.2Zeit dummy ["Dropgenerator.2: ",{"text":"Zeit bis ein Barren erscheint","bold":true}]

# Spieler in einem Umkreis von 15 Metern erhalten für Bronze-, Eisen- und Goldgenerator die jeweiligen Rüstungsständer in das Inventar
give @a[distance=..15] minecraft:armor_stand{dropgenerator:"v2gegenstand",display:{Name:'{"text":"Bronze","color":"dark_red","bold":true}',Lore:['"Platziere den Rüstungsständer"','"auf dem Boden"','"um einen Bronzegenerator"','"zu kreieren"']},EntityTag:{Small:true,NoGravity:true,Invisible:true,Tags:["EtiDropG.2Alle","EtiDropG.2Bronze"]} } 16
give @a[distance=..15] minecraft:armor_stand{dropgenerator:"v2gegenstand",display:{Name:'{"text":"Eisen","color":"gray","bold":true}',Lore:['"Platziere den Rüstungsständer"','"auf dem Boden"','"um einen Bronzegenerator"','"zu kreieren"']},EntityTag:{Small:true,NoGravity:true,Invisible:true,Tags:["EtiDropG.2Alle","EtiDropG.2Eisen"]} } 16
give @a[distance=..15] minecraft:armor_stand{dropgenerator:"v2gegenstand",display:{Name:'{"text":"Gold","color":"gold","bold":true}',Lore:['"Platziere den Rüstungsständer"','"auf dem Boden"','"um einen Bronzegenerator"','"zu kreieren"']},EntityTag:{Small:true,NoGravity:true,Invisible:true,Tags:["EtiDropG.2Alle","EtiDropG.2Gold"]} } 16


Variante 1: Zyklus-Funktion
Alle 200, 400 oder 800 Ticks werden die entsprechenden Barren an den Generatoren erzeugt und falls sich der entsprechende Block noch nicht am Generator befindet wird dieser noch platziert.

Editor Icon dropgenerator:v2zyklus.mcfunction
# Falls sich kein Block bei den Generatoren befindet, wird der jeweilige Block platziert
execute at @e[type=minecraft:armor_stand,tag=EtiDropG.2Bronze] run setblock ~ ~ ~ minecraft:bricks keep
execute at @e[type=minecraft:armor_stand,tag=EtiDropG.2Eisen] run setblock ~ ~ ~ minecraft:iron_block keep
execute at @e[type=minecraft:armor_stand,tag=EtiDropG.2Gold] run setblock ~ ~ ~ minecraft:gold_block keep

# Jeden Tick wird der Wert aller Generatoren um eins erhöht
scoreboard players add @e[type=minecraft:armor_stand,tag=EtiDropG.2Alle] PZDropG.2Zeit 1

# Wenn die Generatoren den Wert 20 erreichen erzeugen sie ihren jeweilgen Barren über sich, welcher ein wenig in die Höhe springt
execute at @e[type=minecraft:armor_stand,tag=EtiDropG.2Bronze,scores={PZDropG.2Zeit=20}] run summon minecraft:item ~ ~1 ~ {Item:{id:"minecraft:brick",Count:1b,tag:{dropgenerator:"v2gegenstand",display:{Name:'{"text":"Bronzebarren"}'} } },Motion:[0.0d,0.3d,0.0d],Tags:["EtiDropG.2Alle"] }
execute at @e[type=minecraft:armor_stand,tag=EtiDropG.2Eisen,scores={PZDropG.2Zeit=20}] run summon minecraft:item ~ ~1 ~ {Item:{id:"minecraft:iron_ingot",Count:1b,tag:{dropgenerator:"v2gegenstand",display:{Name:'{"text":"Eisenbarren"}'} } },Motion:[0.0d,0.3d,0.0d],Tags:["EtiDropG.2Alle"] }
execute at @e[type=minecraft:armor_stand,tag=EtiDropG.2Gold,scores={PZDropG.2Zeit=20}] run summon minecraft:item ~ ~1 ~ {Item:{id:"minecraft:gold_ingot",Count:1b,tag:{dropgenerator:"v2gegenstand",display:{Name:'{"text":"Goldbarren"}'} } },Motion:[0.0d,0.3d,0.0d],Tags:["EtiDropG.2Alle"] }

# Je nach Generatortyp wird die Zeit bei 200, 400 oder 800 wieder auf null zurückgesetzt
scoreboard players reset @e[type=minecraft:armor_stand,tag=EtiDropG.2Bronze,scores={PZDropG.2Zeit=200..}] PZDropG.2Zeit
scoreboard players reset @e[type=minecraft:armor_stand,tag=EtiDropG.2Eisen,scores={PZDropG.2Zeit=400..}] PZDropG.2Zeit
scoreboard players reset @e[type=minecraft:armor_stand,tag=EtiDropG.2Gold,scores={PZDropG.2Zeit=800..}] PZDropG.2Zeit


Variante 1: Stopp-Funktion
Das Punktestand-Ziel, die Generatoren sowie die Gegenstände im Inventar wie auch in der Welt liegende werden gelöscht.

Editor Icon dropgenerator:v2stopp.mcfunction
# Das Punktestand-Ziel wird wieder gelöscht
scoreboard objectives remove PZDropG.2Zeit

# Wenn sich an der Stelle der Generatoren ein Block befindet, wird dieser durch Luft ersetzt
execute at @e[type=minecraft:armor_stand,tag=EtiDropG.2Alle] unless block ~ ~ ~ minecraft:air run setblock ~ ~ ~ minecraft:air replace

# Barren die auf dem Boden liegen und Generatoren werden gelöscht
tag @e[type=minecraft:item,nbt={Item:{tag:{dropgenerator:"v2gegenstand"} } }] add EtiDropG.2Alle
kill @e[tag=EtiDropG.2Alle]

# Gegenstände von und für die Generatoren werden aus dem Inventar gelöscht der Spieler gelöscht
clear @a minecraft:armor_stand{dropgenerator:"v2gegenstand"}
clear @a minecraft:brick{dropgenerator:"v2gegenstand"}
clear @a minecraft:iron_ingot{dropgenerator:"v2gegenstand"}
clear @a minecraft:gold_ingot{dropgenerator:"v2gegenstand"}
Advertisement