Koordinaten-Sensor (Befehle)

Aus Technik Wiki
Wechseln zu: Navigation, Suche
Gruppe: Grid Kolben.png
Vorrichtungen

Grid Roter Sand blass.png mit Mechaniken

Grid Redstone blass.png mit Redstone
                Hier:
Grid Befehlsblock.png mit Befehlen
Verfügbar in:
Wiki Redstone-Welt.png Redstone-Welt

Ein Koordinaten-Sensor wird dazu genutzt um die eindeutige Position eines Spielers zu erfassen und auszugeben. Die Position wird über die drei Koordinaten X, Y und Z gespeichert.

Inhaltsverzeichnis

Variante 1[Bearbeiten | Quelltext bearbeiten]

Koordinaten-Sensor (Befehle) Bild 1.1.png

Dieser Koordinaten-Sensor ermöglicht das Ausgeben der Koordinaten als Titel-Nachricht über der Schnellleiste. Dazu wählt man den magischen Kompass aus und solange man diesen ausgewählt hat, werden einem die Koordinaten angezeigt.

Einschalten

Wird der Hebel umgelegt, startet der Befehlsblock und führt die Start-Funktion aus.

Wiederholen

Mit dem Wiederhol-Befehlsblock wird jeden Tick die Zyklus-Funktion ausgeführt.

Ausschalten

Sobald der Hebel wieder in Ausgangsstellung zurück gelegt wurde, wird die Stopp-Funktion aktiviert.


Befehlsblöcke mit Befehlen:



Variante 1: Start-Funktion
Die Start-Funktion erstellt das Punktestand-Ziel und Spieler erhalten den magischen Kompass.

Editor Icon.png koordinaten-sensor:v1start.mcfunction
# Ein Punkte-Ziel wird angelegt um die Koordinaten zu speichern.
scoreboard objectives add PZKoordS.1Wert dummy ["Koordinaten-Sensor.1: ",{"text":"Koordinaten","bold":true}]

# Den Spielern im Umkreis von 15 Blöcken wird ein Kompass gegeben, mit dem sie die Koordinaten messen können.
give @a[distance=..15] minecraft:compass{EigKoordS.1Alle:true,EigKoordS.1Sensor:true,Enchantments:[{id:-1}],display:{Name:'{"text":"Koordinaten-Sensor","color":"dark_purple","bold":true}',Lore:['"Wähle den Kompass aus"','"um die Koordinaten"','"anzuzeigen zu lassen."'] } }

# Der Chunk wird aktiv, damit der Sensor auch weit ab noch funktioniert.
forceload add ~ ~


Variante 1: Zyklus-Funktion
Die Zyklus-Funktion ruft vom Spieler aus die Sensor-Funktion auf, wenn dieser den Kompass ausgewählt hat.

Editor Icon.png koordinaten-sensor:v1zyklus.mcfunction
# Wenn der Spieler den Kompass ausgewählt hat, erhält er zur Erkennung ein Etikett.
tag @a[nbt={SelectedItem:{tag:{EigKoordS.1Sensor:true} } }] add EtiKoordS.1Ausgewaehlt

# Spieler die das Etikett besitzen laden von sich aus die Sensor-Funktion.
execute as @a[tag=EtiKoordS.1Ausgewaehlt] run function koordinaten-sensor:v1sensor

# Wenn der Kompass nicht mehr ausgewählt wird, wird die Nachricht über der Schnellleiste geleert.
title @a[tag=!EtiKoordS.1Ausgewaehlt,tag=EtiKoordS.1Auswahl] actionbar [""]

# Um zu erfassen ob der Spieler gerade den Kompass ausgewählt hat oder ihn nicht mehr auswählt, wird ihm ein Etikett gegeben oder entfernt.
tag @a[tag=EtiKoordS.1Ausgewaehlt,tag=!EtiKoordS.1Auswahl] add EtiKoordS.1Auswahl
tag @a[tag=!EtiKoordS.1Ausgewaehlt,tag=EtiKoordS.1Auswahl] remove EtiKoordS.1Auswahl

# Das Etikett wird wieder entfernt.
tag @a[tag=EtiKoordS.1Ausgewaehlt] remove EtiKoordS.1Ausgewaehlt


Variante 1: Sensor-Funktion
Die Sensor-Funktion ließt die drei Koordinaten des Spielers aus und gibt diese mit einer Titel-Nachricht aus.

Editor Icon.png koordinaten-sensor:v1sensor.mcfunction
# Die drei Koordinaten X, Y und Z werden in jeweils eine Variable gespeichert und dabei wird die Koordinate von einer Kommazahl in eine Ganzzahl umgewandelt.
execute store result score VarKoordS.1X PZKoordS.1Wert run data get entity @s Pos[0]
execute store result score VarKoordS.1Y PZKoordS.1Wert run data get entity @s Pos[1]
execute store result score VarKoordS.1Z PZKoordS.1Wert run data get entity @s Pos[2]

# Die drei Koordinaten werden mit Hilfe der drei Variablen ausgegeben.
title @s actionbar ["",{"text":"X == ","color":"gray","bold":true},{"score":{"name":"VarKoordS.1X","objective":"PZKoordS.1Wert"},"color":"red","bold":true},{"text":" Y == ","color":"gray","bold":true},{"score":{"name":"VarKoordS.1Y","objective":"PZKoordS.1Wert"},"color":"dark_green","bold":true},{"text":" Z == ","color":"gray","bold":true},{"score":{"name":"VarKoordS.1Z","objective":"PZKoordS.1Wert"},"color":"blue","bold":true}]

Variante 1: Stopp-Funktion
Die Stopp-Funktion löscht das Punktestand-Ziel wieder, entfernt das Etikett und löscht den Kompass mit Verzauberungsschimmer.

Editor Icon.png koordinaten-sensor:v1stopp.mcfunction
# Das Punkte-Ziel wird entfernt.
scoreboard objectives remove PZKoordS.1Wert

# Das Etikett zur Auswahl des Kompasses, wird wieder entfernt, falls es noch vorhanden war.
tag @a[tag=EtiKoordS.1Auswahl] remove EtiKoordS.1Auswahl

# Der Kompass wird aus dem Inventar entfernt.
clear @a minecraft:compass{EigKoordS.1Alle:true}

# Falls der Kompass auf dem Boden geworfen wurde, wird der Drop entfernt.
kill @e[type=minecraft:item,nbt={Item:{tag:{EigKoordS.1Alle:true} } }]

# Der aktive Chunk wird wieder entladen.
forceload remove ~ ~


Disambig color.svg
 
Grid Grasblock.png
Auch im Minecraft Wiki wird das Thema dieser Technik behandelt:
Koordinaten