Technik Wiki
Advertisement
Technik Wiki
Gruppe: Grid Werkbank.png
Grundmodule

Grid Roter Sand blass.png mit Mechaniken

Grid Redstone.png mit Redstone
                Hier:
Grid Befehlsblock.png mit Befehlen
Verfügbar in:
Wiki Redstone-Welt.png Redstone-Welt
Wiki Redstone-Welt.png
Alle neuen oder überarbeiteten Techniken auf dieser Seite sind noch nicht in der aktuellen Redstone-Welt vorhanden.
In einem der nächsten Updates werden sie dort hinzugefügt werden.

Das Signal-Element ist ein Glied einer Signalleitung. Es sendet ein Signal von einem Signalgeber visuell an einen Signalempfänger. Das Signal hierbei kann "wahr" und "falsch" beinhalten, es kann aber auch Zahlenwerte besitzen.

Grundlagen[]

Das Signal-Element baut auf folgende Blockeigenschaften auf:

Lupe.png Hauptartikel: Redstone-Element
Lupe.png Hauptartikel: Befehle-Parser
Lupe.png Hauptartikel: Befehlssignal

Variante 1[]

Signal-Element (Befehle) Bild 1.1.png Signal-Element (Befehle) Bild 1.2.png Signal-Element (Befehle) Bild 1.3.png Signal-Element (Befehle) Bild 1.4.png

Dieses Signal-Element gibt ein Signal vom Spieler aus und sendet es in Richtung eines Empfängers. Ist es beim Empfänger angekommen, leuchtet der Empfänger für 15 Sekunden auf.

Einschalten
  • Befehl 1.1 Den Spielern in Umkreis von 15 Blöcken werden 16 Rüstungsständer gegeben. Diese haben spezielle NBT-Eigenschaften um sie von normalen Rüstungsständern im Inventar unterscheiden zu können. Ebenfalls verfügen sie einen Verzauberungsschimmer und einen eigenen Namen. Wenn sie platziert werden, werden weitere Eigenschaften sichtbar. So sind sie klein, werden von der Schwerkraft nicht beeinflusst und zeigen ihren eigenen Namen an. Zudem besitzen sie spezielle Etiketten, um sie als Objekte von anderen Rüstungsständern unterscheiden zu können.
Wiederholen
  • Befehl 1.2 Alle Spieler die die Rüstungsständer mit der speziellen Eigenschaft in der Schnellleiste ausgewählt haben, erhalten ein Etikett zur Markierung.
  • Befehl 1.3 Wenn Spieler das Etikett fürs Ausgewählt sein haben, aber noch nicht das Auswahl-Etikett, so haben sie erst in diesem Tick den Rüstungsständer ausgewählt. Nur genau in diesem Tick wird eine Partikelwolke erzeugt, die eine theoretische Lebenszeit von drei Jahren hat und bestimmte Etiketten besitzt. Sie wird aber nur erzeugt, wenn sich in einem Radius von 25 Blöcken um den Spieler, der den Rüstungsständer ausgewählt hat, sich bereits ein Rüstungsständer als Objekt in der Welt befindet, existiert.
  • Befehl 1.4 Anschließend bekommt er das Auswahl-Etikett, damit der Spieler markiert ist und nicht eine weitere Partikelwolke erzeugt wird.
  • Befehl 1.5 Falls der Spieler die Rüstungsständer in der Schnellleiste abgewählt hat, besitzt er kein Ausgewählt-Etikett, jedoch das Auswahl-Etikett. Dieses wird dann auch entfernt.
  • Befehl 1.6 Zu guter letzt wird das Etikett wieder entfernt, sodass es immer nur in dem Tick kurzeitig vorhanden ist, in dem der Spieler tatsächlich die Rüstungsständer ausgewählt hat.
  • Befehl 1.7 Damit die unsichtbare Partikelwolke für Spieler etwas sichtbarer wird, wird an deren aktuellen Position ein Partikel erzeugt, dass das Abbauen von Redstone-Blöcken imitiert.
  • Befehl 1.8 Damit die Partikelwolke in die Richtung des Rüstungsständers bewegt wird, wird ein Teleport-Befehl ausgeführt, der zuvor die Blickrichtung auf das Ziel setzt.
  • Befehl 1.9 Sobald die Partikelwolke das Ziel, also den Empfänger erreicht hat, soll dieser aufleuchten und die Partikelwolke soll verschwinden. Dazu wird dem Empfänger-Rüstungsständer ein Leucht-Effekt für 15 Sekunden gegeben. Der Erfolg dieses Befehls wird anschließend in die Lebensdauer der Partikelwolke gespeichert, sodass sie dabei verschwindet.
Ausschalten
  • Befehl 1.10 Es wird in allen Inventaren der Spieler nachgeschaut, ob sich dort Rüstungsständer mit der speziellen Eigenschaft befinden. Falls ja, werden diese und nur diese aus dem Inventar entfernt.
  • Befehl 1.11 Das Auswahl-Etikett kann unter bestimmten Umständen noch vorhanden sein, daher wird es nachträglich noch entfernt. So zum Beispiel, wenn man den Rüstungsständer ausgewählt hat und dann den Hebel für das Ausschalten wieder umgelegt hat.
  • Befehl 1.12 Es kann sein, dass manche Spieler die Rüstungsständer auf den Boden geworfen haben, sodass sie nicht mehr im Inventar vorhanden sind. Damit sie dennoch gelöscht werden, wird ihnen ein Etikett gegeben, dass sie mit dem gleichen Etikett markiert, dass alle Objekte besitzen die beim Einschalten oder Benutzen erzeugt wurden.
  • Befehl 1.13 Alle Objekte mit diesem speziellen Etikett werden gelöscht und sind damit weg.

Befehlsblöcke mit Befehlen:
give @a[distance=..15] minecraft:armor_stand{EigSigEl.1Alle:true,EigSigEl.1Signal:true,Enchantments:[{id:-1}],display:{Name:'{"text":"Signal-Geber","color":"yellow","bold":true}',Lore:['"Platziere den Rüstungsständer"','"um einen Empfänger"','"zu erstellen und wähle"','"den Rüstungsständer kurz aus,"','"um ein Signal an den nächsten"','"Empfänger weiterzuleiten."'] },EntityTag:{Small:true,NoGravity:true,CustomNameVisible:true,CustomName:'{"text":"Signal-Empfänger","color":"red","bold":true}',Tags:["EtiSigEl.1Alle","EtiSigEl.1Empfaenger"] } } 16


tag @a[nbt={SelectedItem:{tag:{EigSigEl.1Signal:true} } }] add EtiSigEl.1Ausgewaehlt
execute at @a[tag=EtiSigEl.1Ausgewaehlt,tag=!EtiSigEl.1Auswahl] if entity @e[distance=..25,type=minecraft:armor_stand,tag=EtiSigEl.1Empfaenger] run summon minecraft:area_effect_cloud ~ ~ ~ {Duration:2147483647,Tags:["EtiSigEl.1Alle","EtiSigEl.1Signal"]}
tag @a[tag=EtiSigEl.1Ausgewaehlt,tag=!EtiSigEl.1Auswahl] add EtiSigEl.1Auswahl
tag @a[tag=!EtiSigEl.1Ausgewaehlt,tag=EtiSigEl.1Auswahl] remove EtiSigEl.1Auswahl
tag @a[tag=EtiSigEl.1Ausgewaehlt] remove EtiSigEl.1Ausgewaehlt
execute at @e[type=minecraft:area_effect_cloud,tag=EtiSigEl.1Signal] run particle minecraft:block minecraft:redstone_block ~ ~ ~ 0 0 0 0.1 1 force @a[distance=..25]
execute as @e[type=minecraft:area_effect_cloud,tag=EtiSigEl.1Signal] at @s facing entity @e[type=minecraft:armor_stand,tag=EtiSigEl.1Empfaenger,sort=nearest,limit=1] eyes run teleport @s ^ ^ ^0.3
execute as @e[type=minecraft:area_effect_cloud,tag=EtiSigEl.1Signal] at @s if entity @e[distance=..1,type=minecraft:armor_stand,tag=EtiSigEl.1Empfaenger,sort=nearest,limit=1] store result entity @s Duration int 1 run effect give @e[distance=..1,type=minecraft:armor_stand,tag=EtiSigEl.1Empfaenger,sort=nearest,limit=1] minecraft:glowing 15 1 false


clear @a minecraft:armor_stand{EigSigEl.1Alle:true}
tag @a[tag=EtiSigEl.1Auswahl] remove EtiSigEl.1Auswahl
tag @e[type=minecraft:item,nbt={Item:{tag:{EigSigEl.1Alle:true} } }] add EtiSigEl.1Alle
kill @e[tag=EtiSigEl.1Alle]

Variante 2[]

Signal-Element (Befehle) Bild 2.1.png Signal-Element (Befehle) Bild 2.2.png Signal-Element (Befehle) Bild 2.3.png Signal-Element (Befehle) Bild 2.4.png

Das Signal-Element kann dazu genutzt werden, um gelben Beton in einem Kubus-Bereich mit einer Kantenlänge von 30 Blöcken in roten umzuwandeln und auch umgekehrt. Dabei wird die Anzahl der umgewandelten Betonblöcke gespeichert und angezeigt. Spezielle Rüstungsständer die auf diesen Betonblöcken stehen, leuchten dabei auf, falls der Beton die Farbe rot besitzt.

Einschalten
  • Befehl 2.1 Es wird ein Punkte-Ziel erzeugt, dass nur fürs reine Speichern von Punkteständen verwendet wird. Es besitzt darüber hinaus einen JSON-Text der noch weitere Details angibt.
  • Befehl 2.2 Allen Spielern im Umkreis von 15 Blöcken erhalten 16 Rüstungsständer mit speziellen Eigenschaften. Sie besitzen auch einen Verzauberungsschimmer und eigene Namen, sowohl als Gegenstand wie auch als Objekt. Werden diese platziert, so zeigt sich, dass sie kleine, schwerelos und einen eigenen Namen besitzen. Der Name wird dabei auch angezeigt und sie besitzen spezielle Etiketten.
  • Befehl 2.3 Ebenfalls erhalten die gleichen Spieler auch 64 gelben Beton, den man unter die Rüstungsständer platzieren kann, sodass sie sich verfärben können.
Wiederholen
  • Befehl 2.4 Alle Spieler die die Rüstungsständer in der Schnellleiste ausgewählt haben. erhalten zur Markierung ein Etikett.
  • Befehl 2.5 Spieler die gerade in dem Tick die Rüstungsständer ausgewählt haben, speichern in ihrem Punkte-Ziel wie viele gelben Betonblöcke sie in einem Kubus-Bereich von 30 Blöcken Kantenlänge in roten Beton umwandeln konnten.
  • Befehl 2.6 In der gleichen Aktion wird anschließend auch diese Zahl der umgewandelten Blöcke im Chat dem Spieler direkt angezeigt.
  • Befehl 2.7 Wenn der Spieler die Rüstungsständer nicht mehr ausgewählt hat, wird genau in diesem Tick wieder die Anzahl der umgewandelten Blöcke gezählt. Diesmal jedoch von rot zu gelb.
  • Befehl 2.8 Direkt im Anschluss wird im Chat abermals die genaue Anzahl der umgewandelten Blöcke im Chat angezeigt.
  • Befehl 2.9 Das Auswahl-Etikett wird dem Spieler gegeben, damit nur genau in diesem einen Augenblick die Umwandlung der Blöcke stattfindet.
  • Befehl 2.10 Das auswahl-Etikett wird wieder entfernt, sofern die Spieler die Rüstungsständer nicht mehr auswählen.
  • Befehl 2.11 Das Etikett für das Auswählen des Rüstungsständers wird entfernt, sodass es immer im gleichen Tick kurzeitig vorhanden ist, solange die Rüstungsständer ausgewählt sind.
  • Befehl 2.12 Alle Empfänger-Rüstungsständer, die auf einem roten Betonblock stehen, leuchten für eine Sekunde auf.
Ausschalten
  • Befehl 2.13 Das Punkte-ziel wird entfernt. Dadurch werden alle Werte die der Spieler besaß ebenfalls entfernt.
  • Befehl 2.14 Rüstungsständer mit der speziellen Eigenschaft werden aus allen Spieler-Inventaren entfernt.
  • Befehl 2.15 Der gelbe Beton wird ebenfalls, sofern er die spezielle Eigenschaft besitzt aus den Inventaren entfernt.
  • Befehl 2.16 Das Auswahl-Etikett wird entfernt, falls es beim Ausschalten vorhanden war.
  • Befehl 2.17 Alle gedroppten Rüstungsständer, erhalten ein Etikett, dass sie markiert, sodass sie im Anschluss gelöscht werden können.
  • Befehl 2.18 Alle Objekte mit dem Etikett werden gelöscht.

Befehlsblöcke mit Befehlen:
scoreboard objectives add PZSigEl.2Wert dummy ["Signal-Element.2: ",{"text":"Wert der Signale","bold":true}]
give @a[distance=..15] minecraft:armor_stand{EigSigEl.2Alle:true,EigSigEl.2Signal:true,Enchantments:[{id:-1}],display:{Name:'{"text":"Empfänger-Signal","color":"red","bold":true}',Lore:['"Platziere den Rüstungsständer"','"um einen Empfänger"','"zu erstellen und wähle"','"den Rüstungsständer kurz aus,"','"um ein Signal an den nächsten"','"Empfänger weiterzuleiten."'] },EntityTag:{Small:true,NoGravity:true,CustomName:'{"text":"Empfänger-Signal","color":"red","bold":true}',Tags:["EtiSigEl.2Alle","EtiSigEl.2Empfaenger"] } } 16
give @a[distance=..15] minecraft:yellow_concrete{EigSigEl.2Alle:true} 64


tag @a[nbt={SelectedItem:{tag:{EigSigEl.2Signal:true} } }] add EtiSigEl.2Ausgewaehlt
execute as @a[tag=EtiSigEl.2Ausgewaehlt,tag=!EtiSigEl.2Auswahl] at @s store result score @s PZSigEl.2Wert run fill ~-15 ~-15 ~-15 ~15 ~15 ~15 minecraft:red_concrete replace minecraft:yellow_concrete
execute as @a[tag=EtiSigEl.2Ausgewaehlt,tag=!EtiSigEl.2Auswahl] run tellraw @s ["Signal-Element.2:\n",{"text":"Signale == ","color":"yellow","bold":true},{"score":{"name":"@s","objective":"PZSigEl.2Wert"},"color":"dark_purple","bold":true}]
execute as @a[tag=!EtiSigEl.2Ausgewaehlt,tag=EtiSigEl.2Auswahl] at @s store result score @s PZSigEl.2Wert run fill ~-15 ~-15 ~-15 ~15 ~15 ~15 minecraft:yellow_concrete replace minecraft:red_concrete
execute as @a[tag=!EtiSigEl.2Ausgewaehlt,tag=EtiSigEl.2Auswahl] run tellraw @s ["Signal-Element.2:\n",{"text":"Signale == ","color":"red","bold":true},{"score":{"name":"@s","objective":"PZSigEl.2Wert"},"color":"dark_purple","bold":true}]
tag @a[tag=EtiSigEl.2Ausgewaehlt,tag=!EtiSigEl.2Auswahl] add EtiSigEl.2Auswahl
tag @a[tag=!EtiSigEl.2Ausgewaehlt,tag=EtiSigEl.2Auswahl] remove EtiSigEl.2Auswahl
tag @a[tag=EtiSigEl.2Ausgewaehlt] remove EtiSigEl.2Ausgewaehlt
execute as @e[type=minecraft:armor_stand,tag=EtiSigEl.2Empfaenger] at @s if block ~ ~-1 ~ minecraft:red_concrete run effect give @s minecraft:glowing 1 1 false


scoreboard objectives remove PZSigEl.2Wert
clear @a minecraft:armor_stand{EigSigEl.2Alle:true}
clear @a minecraft:yellow_concrete{EigSigEl.2Alle:true}
tag @a[tag=EtiSigEl.2Auswahl] remove EtiSigEl.2Auswahl
tag @e[type=minecraft:item,nbt={Item:{tag:{EigSigEl.2Alle:true} } }] add EtiSigEl.2Alle
kill @e[tag=EtiSigEl.2Alle]

Variante 3[]

Signal-Element (Befehle) Bild 3.1.png Signal-Element (Befehle) Bild 3.2.png Signal-Element (Befehle) Bild 3.3.png Signal-Element (Befehle) Bild 3.4.png

Dieses Signal-Element sendet bei Auswahl des Rüstungsständers ein sichtbares Partikel-Signal an einen in der stehenden Empfänger-Rüstungsständer. Die Entfernung vom Spieler und dem Empfänger lässt das Signal in verschied

Einschalten
  • Befehl 3.1 Auf dem Wiederhol-Befehlsblock befindet sich ein Hebel. Legt man ihn um, wird zuerst der Befehlsblock mit der Start-Funktion signal-element:v3start aktiviert.
Wiederholen
Ausschalten

Befehlsblöcke mit Befehlen:



Datenpaket
  • Grundmodule


Variante 3: Start-Funktion
Die Start-Funktion erstellt das Punkte-Ziel und gibt den Spielern den Rüstungsständer und gelbe Betonblöcke.

Editor Icon.png signal-element:v3start.mcfunction
# Das Punkte-Ziel wird erstellt.
scoreboard objectives add PZSigEl.3Wert dummy ["Signal-Element.2: ",{"text":"Wert der Signale","bold":true}]

# Spielern im Umkreis von 15 Blöcken werden 16 Rüstungsständer mit speziellen Eigenschaften gegeben und ebenfalls werden 64 gelbe Betonblöcke gegeben.
give @a[distance=..15] minecraft:armor_stand{EigSigEl.3Alle:true,EigSigEl.3Signal:true,Enchantments:[{id:-1}],display:{Name:'{"text":"Signal-Geber","color":"yellow","bold":true}',Lore:['"Platziere den Rüstungsständer"','"um einen Empfänger"','"zu erstellen und wähle"','"den Rüstungsständer kurz aus,"','"um ein Signal an den nächsten"','"Empfänger weiterzuleiten."'] },EntityTag:{Small:true,NoGravity:true,CustomNameVisible:true,CustomName:'{"text":"Signal-Empfänger","color":"red","bold":true}',Tags:["EtiSigEl.3Alle","EtiSigEl.3Empfaenger"] } } 16
give @a[distance=..15] minecraft:yellow_concrete{EigSigEl.3Alle:true} 64

# Der Chunk wird dauerhaft geladen.
forceload add ~ ~

Variante 3: Zyklus-Funktion
Die Zyklus-Funktion erfasst das Auswählen des Rüstungsständers, gibt dem Signal eine Farbe und dem Empfänger eine Blockfarbe.

Editor Icon.png signal-element:v3zyklus.mcfunction
# Es wird ein Etikett vergeben, wenn man den Rüstungsständer in der Schnellleiste ausgewählt hat.
tag @a[nbt={SelectedItem:{tag:{EigSigEl.3Signal:true} } }] add EtiSigEl.3Ausgewaehlt

# Wenn Spieler gerade den Rüstungsständer ausgewählt haben, wird eine Partikelwolke erzeugt, sofern ein Empfänger-Rüstungsständer in einem Umkreis von 30 Blöcken vorhanden ist.
execute at @a[tag=EtiSigEl.3Ausgewaehlt,tag=!EtiSigEl.3Auswahl] if entity @e[distance=..30,type=minecraft:armor_stand,tag=EtiSigEl.3Empfaenger] run summon minecraft:area_effect_cloud ~ ~ ~ {Duration:2147483647,Tags:["EtiSigEl.3Alle","EtiSigEl.3Signal"]}

# Es wird ein Etikett vergeben oder entfernt, wenn der Spieler den Rüstungsständer gerade ausgewählt hat oder ihn abgewählt hat.
tag @a[tag=EtiSigEl.3Ausgewaehlt,tag=!EtiSigEl.3Auswahl] add EtiSigEl.3Auswahl
tag @a[tag=!EtiSigEl.3Ausgewaehlt,tag=EtiSigEl.3Auswahl] remove EtiSigEl.3Auswahl

#Das Etikett wird wieder entfernt, damit es immer in dem Tick vorhanden ist, in dem der Rüstungsständer ausgewählt wurde.
tag @a[tag=EtiSigEl.3Ausgewaehlt] remove EtiSigEl.3Ausgewaehlt

# Die Partikelwolke bekommt ihren Wert um eins erhöht. Falls noch keinen Wert besitzt wird null angenommen.
scoreboard players add @e[type=minecraft:area_effect_cloud,tag=EtiSigEl.3Signal] PZSigEl.3Wert 1

# Je nach dem welchen Wert die Partikelwolke besitzt, werden die Partikel anders gefäbrt sein.
execute at @e[type=minecraft:area_effect_cloud,tag=EtiSigEl.3Signal,scores={PZSigEl.3Wert=1..10}] run particle minecraft:block minecraft:yellow_concrete ~ ~ ~ 0 0 0 0.1 1 force @a[distance=..25]
execute at @e[type=minecraft:area_effect_cloud,tag=EtiSigEl.3Signal,scores={PZSigEl.3Wert=11..20}] run particle minecraft:block minecraft:red_concrete ~ ~ ~ 0 0 0 0.1 1 force @a[distance=..25]
execute at @e[type=minecraft:area_effect_cloud,tag=EtiSigEl.3Signal,scores={PZSigEl.3Wert=21..60}] run particle minecraft:block minecraft:purple_concrete ~ ~ ~ 0 0 0 0.1 1 force @a[distance=..25]

# Wenn ein Empfänger-Rüstungsständer irgend einen Wert über null besitzt, wird sein Wert um eins verringert.
scoreboard players remove @e[type=minecraft:armor_stand,tag=EtiSigEl.3Empfaenger,scores={PZSigEl.3Wert=1..}] PZSigEl.3Wert 1

# Die Partikelwolke wird so ausgerichtet, dass sie zum nächsten Empfänger blickt und wird anschließend einen halben Meter vorwärts bewegt.
execute as @e[type=minecraft:area_effect_cloud,tag=EtiSigEl.3Signal] at @s facing entity @e[type=minecraft:armor_stand,tag=EtiSigEl.3Empfaenger,sort=nearest,limit=1] eyes run teleport @s ^ ^ ^0.5

# Wenn die Partikelwolke den Empfänger-Rüstungsständer erreicht hat, wird ihr Wert auf den Rüstungsständer übertragen und sie selbst bekommt die Lebensdauer auf den Wert eins gesetzt, sodass sie im nächsten Tick verschwindet.
execute as @e[type=minecraft:area_effect_cloud,tag=EtiSigEl.3Signal,scores={PZSigEl.3Wert=1..}] at @s if entity @e[distance=..1,type=minecraft:armor_stand,tag=EtiSigEl.3Empfaenger,sort=nearest,limit=1] store success entity @s Duration int 1 run scoreboard players operation @e[distance=..1,type=minecraft:armor_stand,tag=EtiSigEl.3Empfaenger,sort=nearest,limit=1] PZSigEl.3Wert = @s PZSigEl.3Wert

# Empfänger-Rüstungsständer leuchten solange auf, wie sie noch einen Wert über null besitzen.
effect give @e[type=minecraft:armor_stand,tag=EtiSigEl.3Empfaenger,scores={PZSigEl.3Wert=1..}] minecraft:glowing 1 1 false

# Der Betonblock unter dem Empfänger-Rüstungsständer nimmt die gleiche Farbe an wie das Partikel der Partikelwolke.
execute at @e[type=minecraft:armor_stand,tag=EtiSigEl.3Empfaenger,scores={PZSigEl.3Wert=1..10}] run setblock ~ ~-1 ~ minecraft:yellow_concrete replace
execute at @e[type=minecraft:armor_stand,tag=EtiSigEl.3Empfaenger,scores={PZSigEl.3Wert=11..20}] run setblock ~ ~-1 ~ minecraft:red_concrete replace
execute at @e[type=minecraft:armor_stand,tag=EtiSigEl.3Empfaenger,scores={PZSigEl.3Wert=21..60}] run setblock ~ ~-1 ~ minecraft:purple_concrete replace

Variante 3: Stopp-Funktion
Die Stopp-Funktion löscht das Punkte-Ziel, die Gegenstände im Inventar und die platzierten Objekte.

Editor Icon.png signal-element:v3stopp.mcfunction
# Das Punkte-Ziel wird entfernt.
scoreboard objectives remove PZSigEl.3Wert

# Die Rüstungsständer und gelber Beton wird aus dem Inventar entfernt.
clear @a minecraft:armor_stand{EigSigEl.3Alle:true}
clear @a minecraft:yellow_concrete{EigSigEl.3Alle:true}

# Das eventuell noch vorhandene Etikett wird entfernt.
tag @a[tag=EtiSigEl.3Auswahl] remove EtiSigEl.3Auswahl

# Alle Drops bekommen das gleiche Etikett und alle Objekte insgesamt die dieses Etikett besitzen werden entfernt.
tag @e[type=minecraft:item,nbt={Item:{tag:{EigSigEl.3Alle:true} } }] add EtiSigEl.3Alle
kill @e[tag=EtiSigEl.3Alle]

# Der Chunhk wird entladen.
forceload remove ~ ~


Disambig color.svg
Grid Grasblock.png
Auch im Minecraft Wiki wird das Thema dieser Technik behandelt:
Befehlssignal
Advertisement