Technik Wiki
Registrieren
Advertisement
Gruppe: Grid Klebriger Kolben
Anlagen

Grid Roter Sand blass mit Mechaniken

Grid Redstone blass mit Redstone
                Hier:
Grid Befehlsblock mit Befehlen
Verfügbar in:
Wiki Redstone-Welt Redstone-Welt

Der Tageszeitwandler und -sensor kann nicht nur die Tageszeit exakt angeben, sondern auch sie ändern. Man kann auch die Tageszeit festsetzen, in dem man den Befehl /gamerule doDaylightCycle benutzt.

Variante 1[]

Tageszeitwandler und -sensor (Befehle) Bild 1.1 Tageszeitwandler und -sensor (Befehle) Bild 1.2

Mit diesem Tageszeitsensor lassen sich die Tageszeiten anzeigen und man erhält in einer größeren Reichweite noch die Meldung welcher Tag angebrochen ist.

Einschalten
  • Befehl 1.1 Ein Rüstungsständer wird erstellt, der den Tageszeitsensor darstellt. an ihm wird ein Tageslichtsensor[B1.2] platziert.
  • Befehl 1.3 Ein Punktestand-Ziel für das Speichern der Zeitgeschwindigkeit wird erstellt.
Wiederholen
  • Befehl 1.4 Wenn sich ein beliebiger Spieler in der Nähe von fünf Metern des Sensors befindet, wird der aktuelle Tag, sowie die aktuelle Tageszeit[B1.5] ausgelesen.
  • Befehl 1.6 Ebenfalls wird für das Ausgeben der Tageszeiten[B1.7][B1.8][B1.9] von der Position des Rüstungsständer geprüft ob ein Spieler in fünf Metern Reichweite ist.
  • Befehl 1.10 Wenn ein neuer Tag angebrochen ist, wird dieser in die Chat-Leiste ausgegeben.
Ausschalten
  • Befehl 1.11 An der Position des Rüstungsständers wird der Tageslichtsensor entfernt.
  • Befehl 1.12 Der Rüstungsständer selbst wird entfernt.
  • Befehl 1.13 Das Punktestand-Ziel wird wieder entfernt.

Befehlsblöcke mit Befehlen:
summon minecraft:armor_stand ~-5 ~ ~ {Small:true,Invisible:true,Marker:true,CustomNameVisible:true,CustomName:'{"text":"Tageszeitsensor","color":"gold","bold":true}',Tags:["EtiTagZWS.1Alle","EtiTagZWS.1Sensor"]}
execute at @e[type=minecraft:armor_stand,tag=EtiTagZWS.1Sensor] run setblock ~ ~ ~ minecraft:daylight_detector replace
scoreboard objectives add PZTagZWS.1Zeit dummy ["Tageszeitwandler und -sensor.1: ",{"text":"Tageszeit","bold":true}]


execute at @e[type=minecraft:armor_stand,tag=EtiTagZWS.1Sensor] if entity @p[distance=..50] store result score #VarTagZWS.1Tag PZTagZWS.1Zeit run time query day
execute at @e[type=minecraft:armor_stand,tag=EtiTagZWS.1Sensor] if entity @p[distance=..50] store result score #VarTagZWS.1Tick PZTagZWS.1Zeit run time query daytime
execute if score #VarTagZWS.1Tick PZTagZWS.1Zeit matches 0..5999 at @e[type=minecraft:armor_stand,tag=EtiTagZWS.1Sensor] run title @a[distance=..5] actionbar ["",{"text":"[ ","color":"gold","bold":true},{"text":"Tag ","color":"gray","bold":true},{"score":{"name":"#VarTagZWS.1Tag","objective":"PZTagZWS.1Zeit"},"color":"dark_purple","bold":true},{"text":" (Vormittag) ]","color":"gold","bold":true} ]
execute if score #VarTagZWS.1Tick PZTagZWS.1Zeit matches 6000..11999 at @e[type=minecraft:armor_stand,tag=EtiTagZWS.1Sensor] run title @a[distance=..5] actionbar ["",{"text":"[ ","color":"gold","bold":true},{"text":"Tag ","color":"gray","bold":true},{"score":{"name":"#VarTagZWS.1Tag","objective":"PZTagZWS.1Zeit"},"color":"dark_purple","bold":true},{"text":" (Nachmittag) ]","color":"gold","bold":true} ]
execute if score #VarTagZWS.1Tick PZTagZWS.1Zeit matches 12000..17999 at @e[type=minecraft:armor_stand,tag=EtiTagZWS.1Sensor] run title @a[distance=..5] actionbar ["",{"text":"[ ","color":"gold","bold":true},{"text":"Tag ","color":"gray","bold":true},{"score":{"name":"#VarTagZWS.1Tag","objective":"PZTagZWS.1Zeit"},"color":"dark_purple","bold":true},{"text":" (Vormitternacht) ]","color":"gold","bold":true} ]
execute if score #VarTagZWS.1Tick PZTagZWS.1Zeit matches 18000..24000 at @e[type=minecraft:armor_stand,tag=EtiTagZWS.1Sensor] run title @a[distance=..5] actionbar ["",{"text":"[ ","color":"gold","bold":true},{"text":"Tag ","color":"gray","bold":true},{"score":{"name":"#VarTagZWS.1Tag","objective":"PZTagZWS.1Zeit"},"color":"dark_purple","bold":true},{"text":" (Nachmitternacht) ]","color":"gold","bold":true} ]
execute if score #VarTagZWS.1Tick PZTagZWS.1Zeit matches 0 at @e[type=minecraft:armor_stand,tag=EtiTagZWS.1Sensor] run tellraw @a[distance=..50] ["Tageszeitwandler und -sensor.1:\n",{"text":"Tag ","color":"gray","bold":true},{"score":{"name":"#VarTagZWS.1Tag","objective":"PZTagZWS.1Zeit"},"color":"dark_purple","bold":true},{"text":" ist angebrochen","color":"gray","bold":true} ]


execute at @e[type=minecraft:armor_stand,tag=EtiTagZWS.1Sensor] run setblock ~ ~ ~ minecraft:air replace
kill @e[type=minecraft:armor_stand,tag=EtiTagZWS.1Alle]
scoreboard objectives remove PZTagZWS.1Zeit

Variante 2[]

Tageszeitwandler und -sensor (Befehle) Bild 2.1 Tageszeitwandler und -sensor (Befehle) Bild 2.2

Mit diesem Tageszeitwandler lässt sich die Tageszeit von einmal bis maximal acht mal so lange verlangsamen. Dies lässt sich über einen Rahmen, dessen Rotation des Gegenstands, einstellen.

Einschalten
  • Befehl 2.1 Ein Rahmen mit einer Uhr darin wird erzeugt.
  • Befehl 2.2 Ein Punktestand-Ziel für das Speichern der Verlangsamung des Sonnenstandes wird erstellt.
  • Befehl 2.3 Die Spielregel für den Tag-Nacht-Rhythmus wird auf Stillstand gesetzt.
Wiederholen
  • Befehl 2.4 Wenn sich in der Nähe des Rahmens ein Spieler befindet, wird dessen Gegenstandsrotationswert in seinen Punktestand gespeichert.
  • Befehl 2.5 Ebenfalls wird die aktuelle Rotation als Schnellzugriffsleisten-Nachricht angezeigt.
  • Befehl 2.6 Die Variable für die Verlangsamung wird jeden Tick um eins erhöht.
  • Befehl 2.7 Wenn sie schließlich größer gleich dem Wert der Gegenstands-Rotation ist, wird die Zeit um eins erhöht.
  • Befehl 2.8 Gleichzeitig wird die Verlangsamungs-Variable auf null gesetzt.
Ausschalten
  • Befehl 2.9 Der Rahmen wird wieder gelöscht
  • Befehl 2.12 Das Punktestand-Ziel wird wieder entfernt.
  • Befehl 2.13 Die Spielregel wird wieder auf zirkulierend gesetzt.

Befehlsblöcke mit Befehlen:
summon minecraft:item_frame ~-5 ~ ~ {Facing:1b,Item:{id:"minecraft:clock",Count:1b},Tags:["EtiTagZWS.2Alle","EtiTagZWS.2Wandler"]}
scoreboard objectives add PZTagZWS.2Sonne dummy ["Tageszeitwandler und -sensor.2: ",{"text":"Sonnenstand","bold":true}]
gamerule doDaylightCycle false


execute as @e[type=minecraft:item_frame,tag=EtiTagZWS.2Wandler] at @s if entity @p[distance=..5] store result score @s PZTagZWS.2Sonne run data get entity @s ItemRotation
execute as @e[type=minecraft:item_frame,tag=EtiTagZWS.2Wandler] at @s run title @a[distance=..5] actionbar ["",{"text":"Sonne ","color":"gray","bold":true},{"score":{"name":"@s","objective":"PZTagZWS.2Sonne"},"color":"dark_purple","bold":true},{"text":" mal langsamer","color":"gray","bold":true}]
scoreboard players add VarTagZWS.2Verlangsamung PZTagZWS.2Sonne 1
execute if score VarTagZWS.2Verlangsamung PZTagZWS.2Sonne >= @e[type=minecraft:item_frame,tag=EtiTagZWS.2Wandler,sort=nearest,limit=1] PZTagZWS.2Sonne run time add 1
execute if score VarTagZWS.2Verlangsamung PZTagZWS.2Sonne >= @e[type=minecraft:item_frame,tag=EtiTagZWS.2Wandler,sort=nearest,limit=1] PZTagZWS.2Sonne run scoreboard players set VarTagZWS.2Verlangsamung PZTagZWS.2Sonne 0


kill @e[tag=EtiTagZWS.2Alle]
scoreboard objectives remove PZTagZWS.2Sonne
gamerule doDaylightCycle true

Variante 3[]

Tageszeitwandler und -sensor (Befehle) Bild 3.1 Tageszeitwandler und -sensor (Befehle) Bild 3.2

Mit diesem Tageszeitwandler lässt sich einstellen welche Tageszeit gerade anstehen soll und wie schnell der Tag vorangehen soll. Dazu platziert man einen Rüstungsständer der einen Tageszeitwandler erzeugt, welcher mit einem Wurf einer Uhr ihm entgegen aktiviert werden kann. Man erhält hierbei eine Nachricht mit anklickbaren Optionen.

Einschalten
  • Befehl 3.1 Wenn der Hebel umgelegt wird, wird die Start-Funktion gestartet.
Wiederholen
  • Befehl 3.2 Beim Einschalten wird auch der Wiederhol-Befehlsblock gestartet, der jeden Tick die Zyklus-Funktion lädt.
Ausschalten
  • Befehl 3.3 Wenn der Hebel wieder in Ausgangsstellung zurück gelegt wird, wird die Stopp-Funktion ausgelöst und schaltet alles wieder ab.

Befehlsblöcke mit Befehlen:


Variante 3: Start-Funktion
Die Start-Funktion erstellt ein Punktestand-Ziel, setzt die Variablen, gibt den Spielern Rüstungsständer und Uhren und setzt die Spielregel auf Stillstand.

Editor Icon tageszeitwandler_und_-sensor:v3start.mcfunction
# Das Punktestand-Ziel wird erstellt
scoreboard objectives add PZTagZWS.3Wert trigger ["Tageszeitwandler und -sensor.3: ",{"text":"Wert der Variablen","bold":true}]

# Die Variablen werden gesetzt und dabei wird die Zeit-Variable direkt durch die aktuelle Tageszeit definiert
execute store result score VarTagZWS.3Zeit PZTagZWS.3Wert run time query daytime
scoreboard players set VarTagZWS.3Schnelligkeit PZTagZWS.3Wert 1

# Spielern im Umkreis von 15 Metern wird ein Rüstungsständer und mehrere Uhren ins Inventar gegeben
give @a[distance=..15] minecraft:armor_stand{tageszeitwandler_und_-sensor:"v3gegenstand",display:{Name:'{"text":"Tag-Nacht-Rhythmusanlage","color":"gold","bold":true}',Lore:['"Platziere den"','"Rüstungsständer um"','"die Tag-Nacht-Rhytrmusanlage"','"zu erstellen"']},EntityTag:{DisabledSlots:2039583,Small:true,Invisible:true,NoGravity:true,CustomNameVisible:true,CustomName:'{"text":"Tag-Nacht-Rhythmusanlage","color":"gold","bold":true}',Tags:["EtiTagZWS.3Alle","EtiTagZWS.3TagNachtAnlage"],ArmorItems:[{},{},{},{id:"minecraft:daylight_detector",Count:1b} ] } }
give @a[distance=..15] minecraft:clock{tageszeitwandler_und_-sensor:"v3gegenstand",display:{Lore:['"Wirf mit Q die"','"Uhr auf die"','"Tag-Nacht-Ryhtmusanlage"'] } } 4

# Die Spielregel für den Tag-Nacht-Rhythmus wird auf Stillstand gesetzt
gamerule doDaylightCycle false

Variante 3: Zyklus-Funktion
Die Zyklus-Funktion setzt gegebenfalls einen Tageslichtsensor an dem platzierten Rüstungsständer, lässt den Tageszeitwandler rotieren wenn man eine Uhr zu ihm wirft und lässt dabei alle Optionen in einer Chat-Nachricht ausgeben. Ebenfalls reagiert sie auf die eingaben des Spielers.

Editor Icon tageszeitwandler_und_-sensor:v3zyklus.mcfunction
# Falls an der Position des Rüstungsständers (Tag-Nacht-Rhythmusanlage) kein Tageslichtsensor vorhanden ist, wird einer platziert
execute at @e[type=minecraft:armor_stand,tag=EtiTagZWS.3TagNachtAnlage] unless block ~ ~ ~ minecraft:daylight_detector run setblock ~ ~ ~ minecraft:daylight_detector[inverted=true] replace

# Wenn man eine Uhr in die Nähe der Tag-Nacht-Rhythmusanlage wirft, erhält der Drop ein Etikett, damit dieser einfacher erkannt werden kann
execute at @e[type=minecraft:armor_stand,tag=EtiTagZWS.3TagNachtAnlage] run tag @e[distance=..2,type=minecraft:item,tag=!EtiTagZWS.3Uhr,nbt={Item:{id:"minecraft:clock"} },sort=nearest,limit=1] add EtiTagZWS.3Uhr

# Spieler erhalten nach dem Wurf der Uhr den Wert -1 und erhalten so die Chat-Nachricht und gleichzeitig erhält die Tag-Nacht-Rhythmusanlage den Wert 500 für die Ticks wie lange sie aktiv ist. Anschließend wird die Uhr entfernt
execute at @e[type=minecraft:armor_stand,tag=EtiTagZWS.3TagNachtAnlage] if entity @e[distance=..2,type=minecraft:item,tag=EtiTagZWS.3Uhr,sort=nearest,limit=1] run scoreboard players set @a[distance=..5] PZTagZWS.3Wert -1
execute as @e[type=minecraft:armor_stand,tag=EtiTagZWS.3TagNachtAnlage] at @s if entity @e[distance=..2,type=minecraft:item,tag=EtiTagZWS.3Uhr,sort=nearest,limit=1] run scoreboard players set @s PZTagZWS.3Wert 500
execute at @e[type=minecraft:armor_stand,tag=EtiTagZWS.3TagNachtAnlage] run kill @e[distance=..2,type=minecraft:item,tag=EtiTagZWS.3Uhr,sort=nearest,limit=1]

# Wenn die Tag-Nacht-Rhythmusanlage aktiv ist, wird sie rotiert und lässt Flammen und Quarz-Partikel um sie kreisen, welche die Sonne und den Mond symbolisieren sollen
execute as @e[type=minecraft:armor_stand,tag=EtiTagZWS.3TagNachtAnlage,scores={PZTagZWS.3Wert=1..}] at @s run teleport @s ~ ~ ~ ~2 ~
execute at @e[type=minecraft:armor_stand,tag=EtiTagZWS.3TagNachtAnlage,scores={PZTagZWS.3Wert=1..}] run particle minecraft:item minecraft:fire_charge ^ ^1 ^1 0 0 0 0.01 10 force @a[distance=..25]
execute at @e[type=minecraft:armor_stand,tag=EtiTagZWS.3TagNachtAnlage,scores={PZTagZWS.3Wert=1..}] run particle minecraft:item minecraft:quartz ^ ^1 ^-1 0 0 0 0.01 10 force @a[distance=..25]

# Solange die Wetteranlage mindestens den Wert von eins hat, wird ihr jeden Tick dieser um eins reduziert
scoreboard players remove @e[type=minecraft:armor_stand,tag=EtiTagZWS.3TagNachtAnlage,scores={PZTagZWS.3Wert=1..}] PZTagZWS.3Wert 1

# Wenn die Schnelligkeit des Tag-Nacht-Rhythmus größer gleich eins gestellt wurde, wird die Beschleunigungs-Variable auf den aktuellen Schnelligkeitswerrt gesetzt und anschlie0end wird die Beschleinigungs-Funktion geladen
execute if score VarTagZWS.3Schnelligkeit PZTagZWS.3Wert matches 1.. run scoreboard players operation VarTagZWS.2Beschleunigung PZTagZWS.3Wert = VarTagZWS.3Schnelligkeit PZTagZWS.3Wert
execute if score VarTagZWS.3Schnelligkeit PZTagZWS.3Wert matches 1.. run function tageszeitwandler_und_-sensor:v3beschleunigen

# Wenn der Wert der schnelligkeits-Variable kleiner gleich minus eins ist, wird die Verlangsamungs-Variable um eins reduziert und nur wenn sie den Wert der Verlangsamungs-Variable erreicht hat, wird die Sonne und Mond ein kleines Stück bewegt. Im gleichen Moment wird die Verlangsamungs-Variable wieder auf null gesetzt
execute if score VarTagZWS.3Schnelligkeit PZTagZWS.3Wert matches ..-1 run scoreboard players remove VarTagZWS.2Verlangsamung PZTagZWS.3Wert 1
execute if score VarTagZWS.3Schnelligkeit PZTagZWS.3Wert matches ..-1 if score VarTagZWS.2Verlangsamung PZTagZWS.3Wert <= VarTagZWS.3Schnelligkeit PZTagZWS.3Wert run time add 1
execute if score VarTagZWS.3Schnelligkeit PZTagZWS.3Wert matches ..-1 if score VarTagZWS.2Verlangsamung PZTagZWS.3Wert <= VarTagZWS.3Schnelligkeit PZTagZWS.3Wert run scoreboard players set VarTagZWS.2Verlangsamung PZTagZWS.3Wert 0

# Wenn man den Auslöser aktiviert hat und eine der vier möglichen Tageszeiten angeklickt hat, befindet man sich in der Nähe der aktiven Anlage und besitzt einen bestimmten Wert. Der Wert entscheidet, welche der vier Optionen ausgelöst wird. Danach wird immer die aktuelle Zeit in die Zeit-Variable gespeichert
execute at @e[type=minecraft:armor_stand,tag=EtiTagZWS.3TagNachtAnlage,scores={PZTagZWS.3Wert=1..}] if entity @a[distance=..5,scores={PZTagZWS.3Wert=1}] run time set 1000
execute at @e[type=minecraft:armor_stand,tag=EtiTagZWS.3TagNachtAnlage,scores={PZTagZWS.3Wert=1..}] if entity @a[distance=..5,scores={PZTagZWS.3Wert=2}] run time set 6000
execute at @e[type=minecraft:armor_stand,tag=EtiTagZWS.3TagNachtAnlage,scores={PZTagZWS.3Wert=1..}] if entity @a[distance=..5,scores={PZTagZWS.3Wert=3}] run time set 13000
execute at @e[type=minecraft:armor_stand,tag=EtiTagZWS.3TagNachtAnlage,scores={PZTagZWS.3Wert=1..}] if entity @a[distance=..5,scores={PZTagZWS.3Wert=4}] run time set 18000
execute at @e[type=minecraft:armor_stand,tag=EtiTagZWS.3TagNachtAnlage,scores={PZTagZWS.3Wert=1..}] if entity @a[distance=..5,scores={PZTagZWS.3Wert=1..4}] store result score VarTagZWS.3Zeit PZTagZWS.3Wert run time query daytime

# Hat man auf Schnelligkeits-Option geklickt, so wird die Rotation der Sonne beschleunigt oder verlangsamt
execute at @e[type=minecraft:armor_stand,tag=EtiTagZWS.3TagNachtAnlage,scores={PZTagZWS.3Wert=1..}] if entity @a[distance=..5,scores={PZTagZWS.3Wert=5}] run scoreboard players add VarTagZWS.3Schnelligkeit PZTagZWS.3Wert 1
execute at @e[type=minecraft:armor_stand,tag=EtiTagZWS.3TagNachtAnlage,scores={PZTagZWS.3Wert=1..}] if entity @a[distance=..5,scores={PZTagZWS.3Wert=6}] run scoreboard players remove VarTagZWS.3Schnelligkeit PZTagZWS.3Wert 1

# Wenn die Tag-Nacht-Rhythmusanlage aktiv ist und der Spieler nicht den Wert null besitzt, so erhält er die Chat-Nachricht in der alle Wetteroptionen aufgelistet sind
execute at @e[type=minecraft:armor_stand,tag=EtiTagZWS.3TagNachtAnlage,scores={PZTagZWS.3Wert=1..}] as @a[distance=..5] unless entity @s[scores={PZTagZWS.3Wert=0}] run tellraw @s ["Tageszeitwandler und -sensor.3: ",{"text":"\nzeit = ","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"Tippe für Vormittag"} },"clickEvent":{"action":"run_command","value":"/trigger PZTagZWS.3Wert set 1"} },{"text":"1000","color":"gray","bold":true},{"text":"\nzeit = ","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"Tippe für Nachmittag"} },"clickEvent":{"action":"run_command","value":"/trigger PZTagZWS.3Wert set 2"} },{"text":"6000","color":"gray","bold":true},{"text":"\nzeit = ","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"Tippe Nacht"} },"clickEvent":{"action":"run_command","value":"/trigger PZTagZWS.3Wert set 3"} },{"text":"13000","color":"gray","bold":true},{"text":"\nzeit = ","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"Tippe Mitternacht"} },"clickEvent":{"action":"run_command","value":"/trigger PZTagZWS.3Wert set 4"} },{"text":"18000","color":"gray","bold":true},{"text":"\nzeit == ","bold":true},{"score":{"name":"VarTagZWS.3Zeit","objective":"PZTagZWS.3Wert"},"color":"dark_purple","bold":true},{"text":"\nschnelligkeit (","bold":true},{"text":"+1","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"Tippe für die Dauer +1"} },"clickEvent":{"action":"run_command","value":"/trigger PZTagZWS.3Wert set 5"} },{"text":"!","bold":true},{"text":"-1","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"Tippe für die Dauer -1"} },"clickEvent":{"action":"run_command","value":"/trigger PZTagZWS.3Wert set 6"} },{"text":") == ","bold":true},{"score":{"name":"VarTagZWS.3Schnelligkeit","objective":"PZTagZWS.3Wert"},"color":"dark_purple","bold":true}]

# Spieler die keinen Wert besitzen oder einen über null erhalten die Erlaubnis einen Auslöser zu nutzen und bekommen den Wert null zugewiesen
execute at @e[type=minecraft:armor_stand,tag=EtiTagZWS.3TagNachtAnlage] as @a[distance=..5] unless entity @s[scores={PZTagZWS.3Wert=0}] run scoreboard players enable @s PZTagZWS.3Wert
execute at @e[type=minecraft:armor_stand,tag=EtiTagZWS.3TagNachtAnlage] as @a[distance=..5] unless entity @s[scores={PZTagZWS.3Wert=0}] run scoreboard players set @s PZTagZWS.3Wert 0

Variante 3: Beschleunigungs-Funktion
Die Beschleinigungs-Funktion wird aufgerufen, wenn der Spieler die entsprechende Option gewählt hat, dass die Tageszeit im positiven Bereich beschleunigt werden soll. Dazu ruft sie sich in den meisten Fällen nochmals auf um die gewünschte Beschleunigung zu erzielen.

Editor Icon tageszeitwandler_und_-sensor:v3beschleunigen.mcfunction
# Die Zeit wird um eins erhöht und anschließend die Beschleunigungs-Variable um eins verringert. Diese Funktion wird nochmal aufgerufen, wenn die Beschleunigungs-Variable größer gleich eins ist
time add 1
scoreboard players remove VarTagZWS.2Beschleunigung PZTagZWS.3Wert 1
execute if score VarTagZWS.2Beschleunigung PZTagZWS.3Wert matches 1.. run function tageszeitwandler_und_-sensor:v3beschleunigen

Variante 3: Stopp-Funktion
Die Stopp-Funktion entfernt das Punktestand-Ziel, die Gegenstände im Inventar oder auf dem Boden und setzt die Spielregel wieder auf zirkulierend.

Editor Icon tageszeitwandler_und_-sensor:v3stopp.mcfunction
# Das Punktestand-Ziel wird gelöscht
scoreboard objectives remove PZTagZWS.3Wert

# Der Rüstungsständer und die Uhr werden aus dem Inventar der Spieler entfernt
clear @a minecraft:armor_stand{tageszeitwandler_und_-sensor:"v3gegenstand"}
clear @a minecraft:clock{tageszeitwandler_und_-sensor:"v3gegenstand"}

# Der Tageslichtsensor wird durch Luft ersetzt
execute at @e[type=minecraft:armor_stand,tag=EtiTagZWS.3TagNachtAnlage] run setblock ~ ~ ~ minecraft:air replace

# Alle Gegenstände die auf den Boden geworfen wurden und eine bestimmte Eigenschaft besitzen werden mit einem Etikett ausgestattet. Alle mit diesem Etikett werden gelöscht
tag @e[type=minecraft:item,nbt={Item:{tag:{tageszeitwandler_und_-sensor:"v3gegenstand"} } }] add EtiTagZWS.3Alle
kill @e[tag=EtiTagZWS.3Alle]

# Die Spielregel für den Tag-Nacht-Rhythmus wird wieder auf zirkulierend gestellt
gamerule doDaylightCycle true


Disambig color
Advertisement