Werkzeug-System (Befehle)

Diese Seite wird gerade von Nethonos neu erstellt oder grundlegend überarbeitet.
Fragen und Vorschläge bitte in die Diskussion. Fortschritt:

Gruppe: Unbekannter Gruppenname [[]]	mit Mechaniken	mit Redstone	Hier: mit Befehlen	Noch in keiner Download-Welt enthalten.

Diese neue oder überarbeitete Technik ist noch nicht in der aktuellen Mechanik-Welt vorhanden.

In einem der nächsten Updates wird sie dort hinzugefügt werden.

Erster Test der Funktionen

Variante 1

Unbekannter Gruppenname Folgende Voraussetzungen werden benötigt:

Technik/Befehle Grundmodule Befehl Befehlssignal Grund-Element (Befehle) Signal-Element (Befehle) Signalleitung (Befehle)

Folgende Materialien werden benötigt:

1 Hebel 1 Redstone-Fackel 1 Befehlsblock 1 Wiederhol-Befehlsblock

Dieses Werkzeug-System ermöglicht einem Spieler insbesondere im Überlebensmodus, dass dieser mit einer beliebigen Vorlage:De die mit Haltbarkeit verzaubert ist, vor ihm in einem Radius welcher abhängig von der Verzauberungsstufe ist, ein größeres Feld mit nur einem Schlag zu ernten.

Mit dem BefehlBefehl 1.1 und Befehl 1.2 wird die Funktion gestartet. Die Funktion technik_wiki:werkzeug-system/v1arbeiten wird jeden Tick geladen und dabei wird in Zeile 4 ein Etikett vergeben, wenn der Spieler eine goldene Hacke in der Schnellzugriffsleiste ausgewählt hat.

Befehlsblöcke mit Befehlen:

↑ 1.1:

function technik_wiki:werkzeug-system/v1starten

↑ 1.2:

function technik_wiki:werkzeug-system/v1arbeiten

↑ 1.3:

function technik_wiki:werkzeug-system/v1beenden

technik_wiki:werkzeug-system/v1starten.mcfunction

# Punktestand-Ziele werden erstellt
scoreboard objectives add PZWerkS.1Verz dummy {"text":"Werkzeug-System: Verzauberungsstufe"}
scoreboard objectives add PZWerkS.1Haltb dummy {"text":"Werkzeug-System: Haltbarkeit"}

scoreboard objectives add PZWerkS.1Weizen minecraft.mined:minecraft.wheat {"text":"Werkzeug-System: Weizen geerntet"}
scoreboard objectives add PZWerkS.1Karotte minecraft.mined:minecraft.carrots {"text":"Werkzeug-System: Karotten geerntet"}
scoreboard objectives add PZWerkS.1Kartoff minecraft.mined:minecraft.potatoes {"text":"Werkzeug-System: Kartoffeln geerntet"}
scoreboard objectives add PZWerkS.1Bete minecraft.mined:minecraft.beetroots {"text":"Werkzeug-System: Rote Bete geerntet"}

technik_wiki:werkzeug-system/v1arbeiten.mcfunction

# Etikette vergeben, falls man Ackerpflanzen abbaut
tag @a[scores={PZWerkS.1Weizen=1..}] add EtiWerkS.1Ernte
tag @a[scores={PZWerkS.1Karotte=1..}] add EtiWerkS.1Ernte
tag @a[scores={PZWerkS.1Kartoff=1..}] add EtiWerkS.1Ernte
tag @a[scores={PZWerkS.1Bete=1..}] add EtiWerkS.1Ernte

# Nur für die Spieler wird die Funktion aufgerufen, die tatsächlich eine Ackerpflanze gerntet haben
execute as @a[tag=EtiWerkS.1Ernte] run function technik_wiki:werkzeug-system/v1arbeiten2

# Den Punktestand für das Ernten der Ackerpflanze wieder zurücksetzen
scoreboard players reset @a[scores={PZWerkS.1Weizen=1..}] PZWerkS.1Weizen
scoreboard players reset @a[scores={PZWerkS.1Karotte=1..}] PZWerkS.1Karotte
scoreboard players reset @a[scores={PZWerkS.1Kartoff=1..}] PZWerkS.1Kartoff
scoreboard players reset @a[scores={PZWerkS.1Bete=1..}] PZWerkS.1Bete

# Das Etikett für die Ernte wieder entfernen
tag @a[tag=EtiWerkS.1Ernte] remove EtiWerkS.1Ernte

technik_wiki:werkzeug-system/v1arbeiten2.mcfunction

# Wenn man eine Hacke in der Schnellzugriffsleiste ausgewählt hat, erhält man ein Etikett
tag @s[nbt={SelectedItem:{id:"minecraft:wooden_hoe"} } ] add EtiWerkS.1Hacke
tag @s[nbt={SelectedItem:{id:"minecraft:stone_hoe"} } ] add EtiWerkS.1Hacke
tag @s[nbt={SelectedItem:{id:"minecraft:iron_hoe"} } ] add EtiWerkS.1Hacke
tag @s[nbt={SelectedItem:{id:"minecraft:golden_hoe"} } ] add EtiWerkS.1Hacke
tag @s[nbt={SelectedItem:{id:"minecraft:diamond_hoe"} } ] add EtiWerkS.1Hacke

# Bei Spielern die ihre Hacke mit Haltbarkeit verzaubert haben, wird dessen Verzauberungsstufe in einem Punktestand-Ziel gespeichert
execute store result score @s[nbt={SelectedItem:{tag:{Enchantments:[{id:"minecraft:unbreaking"} ] } } } ] PZWerkS.1Verz run data get entity @s SelectedItem.tag.Enchantments[0].lvl

# Nur wenn die Hacke verzaubert ist, wird die Funktion zwei Blöcke vor dem Spieler aufgerufen
execute as @s[tag=EtiWerkS.1Hacke,scores={PZWerkS.1Verz=1..}] at @s rotated ~90 0 positioned ^2 ^ ^ run function technik_wiki:werkzeug-system/v1arbeiten3

# Die Beschädigung wird um eins erhöht
execute store result score @s[tag=EtiWerkS.1Hacke,scores={PZWerkS.1Verz=1..}] PZWerkS.1Haltb run data get entity @s SelectedItem.tag.Damage
scoreboard players add @s PZWerkS.1Haltb 1
execute store result entity @s[tag=EtiWerkS.1Hacke,scores={PZWerkS.1Verz=1..}] SelectedItem.tag.Damage int 1 run scoreboard players get @s PZWerkS.1Haltb

# Wenn der Spieler eine verzauberte Hacke besaß wird sein Punktestand zurück gesetzt und das Etikett wird entfernt
scoreboard players reset @s[scores={PZWerkS.1Verz=1..}] PZWerkS.1Verz
tag @a[tag=EtiWerkS.1Hacke] remove EtiWerkS.1Hacke

technik_wiki:werkzeug-system/v1arbeiten3.mcfunction

# Bei Stufe 1 und höher
function technik_wiki:werkzeug-system/v1arbeiten4

# Bei Stufe 2
execute if entity @s[scores={PZWerkS.1Verz=2}] positioned ~1 ~ ~1 run function technik_wiki:werkzeug-system/v1arbeiten4
execute if entity @s[scores={PZWerkS.1Verz=2}] positioned ~-1 ~ ~1 run function technik_wiki:werkzeug-system/v1arbeiten4
execute if entity @s[scores={PZWerkS.1Verz=2}] positioned ~1 ~ ~-1 run function technik_wiki:werkzeug-system/v1arbeiten4
execute if entity @s[scores={PZWerkS.1Verz=2}] positioned ~-1 ~ ~-1 run function technik_wiki:werkzeug-system/v1arbeiten4

# Bei Stufe 3 und höher
execute if entity @s[scores={PZWerkS.1Verz=3..}] positioned ~2 ~ ~2 run function technik_wiki:werkzeug-system/v1arbeiten4
execute if entity @s[scores={PZWerkS.1Verz=3..}] positioned ~-2 ~ ~2 run function technik_wiki:werkzeug-system/v1arbeiten4
execute if entity @s[scores={PZWerkS.1Verz=3..}] positioned ~2 ~ ~-2 run function technik_wiki:werkzeug-system/v1arbeiten4
execute if entity @s[scores={PZWerkS.1Verz=3..}] positioned ~-2 ~ ~-2 run function technik_wiki:werkzeug-system/v1arbeiten4

technik_wiki:werkzeug-system/v1arbeiten4.mcfunction

# Ein 3 * 3 Bereich wird geerntet wenn sich vor Ort die Ackerpflanzen befinden
execute if block ~ ~ ~ #technik_wiki:werkzeug-system.pflanzen run setblock ~1 ~ ~ minecraft:air destroy
execute if block ~ ~ ~ #technik_wiki:werkzeug-system.pflanzen run setblock ~ ~ ~ minecraft:air destroy
execute if block ~ ~ ~ #technik_wiki:werkzeug-system.pflanzen run setblock ~-1 ~ ~ minecraft:air destroy

execute if block ~ ~ ~ #technik_wiki:werkzeug-system.pflanzen run setblock ~1 ~ ~1 minecraft:air destroy
execute if block ~ ~ ~ #technik_wiki:werkzeug-system.pflanzen run setblock ~ ~ ~1 minecraft:air destroy
execute if block ~ ~ ~ #technik_wiki:werkzeug-system.pflanzen run setblock ~-1 ~ ~1 minecraft:air destroy

execute if block ~ ~ ~ #technik_wiki:werkzeug-system.pflanzen run setblock ~1 ~ ~-1 minecraft:air destroy
execute if block ~ ~ ~ #technik_wiki:werkzeug-system.pflanzen run setblock ~ ~ ~-1 minecraft:air destroy
execute if block ~ ~ ~ #technik_wiki:werkzeug-system.pflanzen run setblock ~1 ~ ~-1 minecraft:air destroy

technik_wiki:werkzeug-system/v1beenden.mcfunction

# Punktestand-Ziele werden entfernt
scoreboard objectives remove PZWerkS.1Verz
scoreboard objectives remove PZWerkS.1Haltb

scoreboard objectives remove PZWerkS.1Weizen
scoreboard objectives remove PZWerkS.1Karotte
scoreboard objectives remove PZWerkS.1Kartoff
scoreboard objectives remove PZWerkS.1Bete

technik_wiki:werkzeug-system.pflanzen.json.mcfunction

# JSON-Datei
{
"values": [
"minecraft:wheat",
"minecraft:carrots",
"minecraft:potatoes",
"minecraft:beetroots"
]
}

Werkzeug-System (Befehle)

Inhaltsverzeichnis

Variante 1

Fan Feed